Планировщик заданий Windows из Perl с Win32 :: OLE - неверный запрос - PullRequest
Новая
       90

Планировщик заданий Windows из Perl с Win32 :: OLE - неверный запрос

0 голосов
/ 21 октября 2018

Я пытаюсь использовать Win32 :: OLE для создания задачи в системе Windows 10, что-то похожее на SetDefaultPrinterFromSSD.ps1 .Я попытался вручную проверить запрос путем создания той же задачи вручную в графическом интерфейсе планировщика задач, и это, похоже, сработало.

Вот мой тестовый код: 

use File::Basename;
use Win32;
use Win32::OLE; 
$Win32::OLE::Warn = 3; 
use Data::Dumper; 

my ($me, $dirpath, $suffix) = fileparse($0, qr/\.[^.]*/);
my ($system, $login, $domain, $sidbin, $sidtype, $sidtxt) = "";
$login = Win32::LoginName();
Win32::LookupAccountName($system, $login, $domain, $sidbin, $sidtype);

my($Revision, $SubAuthorityCount,@IdentifierAuthorities) = unpack("CCnnn", $sidbin);
unless (($IdentifierAuthorities[0] || $IdentifierAuthorities[1])) {
    my($temp, $temp2, @SubAuthorities) =     unpack("VVV$SubAuthorityCount",$sidbin);

    $sidtxt = "S-$Revision-$IdentifierAuthorities[2]-".join("-",@SubAuthorities);
}

die Win32::OLE->LastError() unless (my $service = Win32::OLE->CreateObject('Schedule.Service'));
$service->Connect;

my $RootFolder = $service->GetFolder('\\');
die Win32::OLE->LastError() unless (my $TaskDefinition = $service->NewTask(0));

die Win32::OLE->LastError() unless (my $regInfo = $TaskDefinition->RegistrationInfo);
$regInfo->{Description} = "Register a perl task as an event $me";
$regInfo->{Author} = "$domain\\$login";
$regInfo->{URI} = "$sidtxt\\$me";

die Win32::OLE->LastError() unless (my $settings = $TaskDefinition->Settings);
$settings->{Enabled} = 1;
$settings->{AllowDemandStart} = 1;
$settings->{DisallowStartIfOnBatteries} = 0;
$settings->{StopIfGoingOnBatteries} = 0;
$settings->{Hidden} = 0;

my @Triggers;
my $TriggerSet;
die Win32::OLE->LastError() unless ($TriggerSet = $TaskDefinition->Triggers);
for (10000..10001) {
    die Win32::OLE->LastError() unless (push @Triggers, $TriggerSet->Create(0));
    $Triggers[$#Triggers]->{Id} = $_;
    $Triggers[$#Triggers]->{Subscription} = 
        "<QueryList>
          <Query Id=\"event$_\" Path=\"Microsoft-Windows-NetworkProfile/Operational\">
            <Select Path=\"Microsoft-Windows-NetworkProfile/Operational\">*[System[(EventID=\"$_\")]]</Select>
          </Query>
        </QueryList>";
    die Win32::OLE->LastError() 
  unless (my $values = $Triggers[$#Triggers]->ValueQueries->Create("eventId", "Event/System/EventID"));
    $Triggers[$#Triggers]->{Enabled} = 1;
}

die Win32::OLE->LastError() unless (my $Action = $TaskDefinition->Actions()->Create(0));
$Action->{Path} = 'C:\Perl64\Bin\Perl.exe';
$Action->{Arguments} = "$0 -f event\${eventID}";

$RootFolder->RegisterTaskDefinition("OLE-Test",$TaskDefinition,6,undef,undef,3);
print Dumper $TaskDefinition->{XmlText};

Если я запускаюкод с RegisterTaskDefinition с установленным флагом TASK_VALIDATE_ONLY (третий параметр = 1), я получаю хороший дамп XML.Все идет нормально.Когда я запускаю код с RegisterTaskDefinition с TASK_CREATE_OR_UPDATE (третий параметр = 6), я получаю эту ошибку: 

    OLE exception from "<Unknown Source>":

    (11,263):Subscription:<QueryList><Query Id="event10000"
    Path="Microsoft-Windows-NetworkProfile/Operational"><Select
    Path="Microsoft-Windows-NetworkProfile/Operational">* 
   [System[(EventID="10000")]]</Select></Query></QueryList>

    Win32::OLE(0.1712) error 0x80073a99: "The specified query is invalid"
        in METHOD/PROPERTYGET "RegisterTaskDefinition" at OLE-test.pl line 63.

Любой, кто достаточно знаком с Win32 :: OLE и XML планировщика задач Windows, чтобы объяснить, что я 'я делаю неправильно?

1 Ответ

0 голосов
/ 21 октября 2018

Атрибут Query Id должен быть числовым.Я получил следующее для работы: 

for (10000..10001) {
    die Win32::OLE->LastError() unless (push @Triggers, $TriggerSet->Create(0));
    $Triggers[$#Triggers]->{Id} = $_;
    $Triggers[$#Triggers]->{Subscription} =
        qq{<QueryList>
          <Query Id="$_" Path="Microsoft-Windows-NetworkProfile/Operational">
            <Select Path="Microsoft-Windows-NetworkProfile/Operational">*[System[(EventID="$_")]]</Select>
          </Query>
        </QueryList>};
    die Win32::OLE->LastError() 
  unless (my $values = $Triggers[$#Triggers]->ValueQueries->Create("eventId", "Event/System/EventID"));
    $Triggers[$#Triggers]->{Enabled} = 1;
}

Соответствующее, магическое изменение соответствует 

    $Triggers[$#Triggers]->{Id} = $_;

и 

    <Query Id="$_" Path="Microsoft-Windows-NetworkProfile/Operational">

Возможно, вы можете изменить оба, чтобы не-numeric, но с этим изменением я создал задачи, которые впоследствии смог просмотреть.

Подумайте об использовании $^X в своем коде, чтобы сделать путь к Perl более динамичным, а не жестко кодировать его как C:\Perl64.

...