ORACLE Как использовать катушку с динамическим расположением катушки

Question

Хорошо, так что я полный новичок с оракулом. Теперь, когда это не так;

Я думаю, вы можете понять, что я пытаюсь сделать ниже. Для каждой найденной хранимой процедуры выведите DDL в имя файла с его именем.

Проблема в том, что я не могу понять, как заставить цель спула получить значение FileName, которое устанавливается курсором.

DECLARE 
objName varchar2(50);
FileName varchar2(50);

cursor curProcs is
    select OBJECT_NAME into objName
      FROM ALL_PROCEDURES WHERE OWNER = 'AMS' 
      ORDER BY OBJECT_NAME; -- get all procs in db
BEGIN
open curProcs;
  if curProcs%ISOPEN THEN
   LOOP
    FETCH curProcs into objName;
    EXIT WHEN curProcs%NOTFOUND;
    FileName := 'C:\ ' || objName || '.PRC.SQL';
    spool FileName; --BREAKS
     DBMS_METADATA.GET_DDL('PROCEDURE',objName);
    spool off;
   END LOOP;
  END IF;
END; 

Есть идеи, где я ошибаюсь? и если у кого-то есть пример этого, я был бы очень признателен.

Я чувствую, что должен танцевать вокруг этого, потому что если я создаю столбец изначально тогда

spool &ColName

я получаю результат, я просто не могу изменить это имя & colname

Спасибо за вашу помощь.

Answer 1

Я нашел лучшее решение без необходимости объявлять / начинать / заканчивать блоки кода или операторы запроса.

Пример имени файла спула с датой и временем может быть достигнут:

<code>
sql> column dt new_value _dt 
sql> select to_char(sysdate,'ddMONyyyy_hh24mi') dt from dual; 
sql> spool &_dt

Имя моего файла:

27JUN2011_1727.lst

Вы даже можете указать расширение файла, если вам нужно (например, .txt). Просто создайте другую переменную.

Источник: http://oracle.ittoolbox.com/groups/technical-functional/oracle-apps-l/variable-file-name-with-spool-1508529

Answer 2

SPOOL - это директива SQL Plus, и вы не можете смешать ее в анонимный блок PL / SQL. Если вы собираетесь делать это исключительно в SQL Plus, я думаю, что общая идея будет заключаться в том, чтобы обрабатывать в два этапа, то есть использовать первый скрипт, который динамически генерирует ссылки на имя файла спула, во второй скрипт, который фактически делает dbms_metadata позвонить.

[Изменить]

This should be close to what you need - maybe a line termination problem, depending on your platform:

    set pagesize 0
    set linesize 300
    spool wrapper.sql
    select
    'spool '||object_name||'.sql'||chr(10)||
    'begin 
    dbms_metadata.get_ddl('||chr(39)||object_type||chr(39)||','||chr(39)||object_name||chr(39)||')'||' end;'||chr(10)||
    '/'||chr(10)||
    'spool off'
    from user_objects
    where object_type = 'PROCEDURE'
;
spool off

Answer 3

Я думаю, что UTL_FILE будет гораздо лучше подходить для ваших нужд здесь. SPOOL действительно должна быть командой, инструктирующей sqlplus записать вывод в файл. Обычно я использую это для таких вещей, как ... "эй, администратор баз данных запускает мой скрипт и отправляет мне вывод"

Сначала вам нужно определить каталог. Синтаксис прост:

CREATE DIRECTORY SQLOUTPUT AS 'c:\temp\';

Теперь вы можете использовать это в своем коде:

DECLARE

  -- Get all procedure from All_Objects
  -- You could expand this to pass in the object_type you are looking for
  CURSOR csr IS
    SELECT object_type
      , object_name
    FROM All_Objects
    WHERE object_type = 'PROCEDURE'
    AND owner = 'AMS';

  -- define a file handler type
  outputfile UTL_FILE.file_type;

BEGIN

FOR c IN csr LOOP

  -- open your file using the procedure name from the cursor
  outputfile := UTL_FILE.fopen('SQLOUTPUT',c.object_name||'.prc.sql','W');

  -- output the metadata results just like DBMS_OUTPUT except to a file
  UTL_FILE.put_line(outputfile, DBMS_METADATA.get_ddl(c.object_type, c.object_name));

  -- make sure to close the file when you are done.
  UTL_FILE.fclose(outputfile);

END LOOP;
  -- go home early today ...
END;