Пакет: исключить определенные файлы из списка выбора

Question

У меня есть несколько txt-файлов, содержащих один и тот же набор переменных с разными параметрами.Я создал пакет для чтения всех txt-файлов из папки и создания списка выбора.Пока все работает нормально.

Теперь я хочу исключить некоторые txt-файлы из списка выбора, поскольку они не содержат переменных (например, readme.txt, information.txt).

Вот код, который я получил до сих пор:

@echo off
setlocal enabledelayedexpansion
set count=0

:: Read in files
for %%x in (*.txt) do (
  set /a count=count+1
  set choice[!count!]=%%x
)

echo.
echo Select one:
echo.

:: Print list of files
for /l %%x in (1,1,!count!) do (
   echo %%x] !choice[%%x]!
   )
echo.

:: Retrieve User input
set /p select=? 
echo.

:: Print out selected filename
echo You chose !choice[%select%]!

for /f "delims=" %%A in ("!choice[%select%]!") do endlocal & set "VAR=%%~A"

:: Read variables from configuration file.

for /f "delims== tokens=1,2" %%G in (%VAR%) do set %%G=%%H

Может кто-нибудь помочь мне исключить вышеупомянутые файлы readme.txt и т. Д., Которые находятся в папке с файлами параметров (то есть, param1.txt,а также param2.txt?

Answer 1

Анализ выходных данных dir cmd, отфильтрованного findstr для исключения имен файлов

:: Read in files
for /f "delims=" %%x in ('
    Dir /B /A-D *.txt ^|findstr /ive "readme\.txt information\.txt"
') do (
  set /a count+=1
  set choice[!count!]=%%x
)