Поддерживать все элементы XML в файле XML

Question

в моем XML-файле элементы не являются постоянными, как, скажем, мой файл

<alpha>
  <a>...</a>
  <b>...</b>
  <c>...</c>
</alpha>
<alpha>
  <a>...</a>
  <c>...</c>
</alpha>
<alpha>
  <a>...</a>
  <b>...</b>
</alpha>
<alpha>
  <a>...</a>
  <b>...</b>
  <c>...</c>
</alpha>

Я хотел сказать, что хочу сохранить все элементы в моем XML-файле, создав несуществующий элемент в наборе, и должен пропустить, если какой-либо элемент существует с использованием xslt. Pls. помогите мне решить эту проблему.

Want OutPut, как показано ниже для несуществующих элементов со значением 0 путем создания в xslt.

**

<alpha>
      <a>...</a>
      <b>...</b>
      <c>...</c>
    </alpha>
    <alpha>
      <a>...</a>
      <b>0</b>
      <c>...</c>
    </alpha>
    <alpha>
      <a>...</a>
      <b>...</b>
      <c>0</c>
    </alpha>
    <alpha>
      <a>...</a>
      <b>...</b>
      <c>...</c>
    </alpha>

**

Answer 1

Простое, немного измененное преобразование идентичности может сделать это:

<xsl:stylesheet 
  version="1.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
>
  <xsl:template match="node() | @*">
    <xsl:copy>
      <xsl:apply-templates select="node() | @*" />
      <xsl:if test="self::alpha">
        <xsl:if test="not(a)"><a>0</a></xsl:if>
        <xsl:if test="not(b)"><b>0</b></xsl:if>
        <xsl:if test="not(c)"><c>0</c></xsl:if>
      </xsl:if>
    </xsl:copy>
  </xsl:template>
</xsl:stylesheet>

Имейте в виду, что приведенное выше не создает элементы a, b, c в этом конкретном порядке (поскольку я не думаю, что это действительно необходимо). Он просто удостоверяется, что все три из них есть, и копирует оставшуюся часть ввода как есть.

Answer 2

XSLT 2.0

    <xsl:template match="a|b|c">
        <xsl:copy-of select="."/>
    </xsl:template>
    <xsl:template match="alpha">
        <xsl:variable name="alpha" select="."/>
        <xsl:variable name="forced">
            <forced>
                <a>0</a>
                <b>0</b>
                <c>0</c>
            </forced>
        </xsl:variable>
        <xsl:copy>
            <xsl:for-each select="$forced/forced/*">
                <xsl:variable name="current" select="name()"/>
                <xsl:choose>
                    <xsl:when test="exists($alpha/*[name() = $current])">
                        <xsl:apply-templates select="$alpha/*[name() = $current]"/>
                    </xsl:when>
                    <xsl:otherwise>
                        <xsl:apply-templates select="$forced/forced/*[name() = $current]"/>
                    </xsl:otherwise>
                </xsl:choose>
            </xsl:for-each>
        </xsl:copy>
    </xsl:template>

XSLT 1.0

<xsl:template match="/root">
    <root>
        <xsl:for-each select="alpha">
                <alpha>
                <xsl:choose>
                    <xsl:when test="a">
                        <xsl:copy-of select="a"/>
                    </xsl:when>
                    <xsl:otherwise>
                        <a>0</a>
                    </xsl:otherwise>
                </xsl:choose>
                <xsl:choose>
                    <xsl:when test="b">
                        <xsl:copy-of select="b"/>
                    </xsl:when>
                    <xsl:otherwise>
                        <b>0</b>
                    </xsl:otherwise>
                </xsl:choose>
                <xsl:choose>
                    <xsl:when test="c">
                        <xsl:copy-of select="c"/>
                    </xsl:when>
                    <xsl:otherwise>
                        <c>0</c>
                    </xsl:otherwise>
                </xsl:choose>
                </alpha>
            </xsl:for-each>
    </root>
</xsl:template>