Проверка существования элемента коллекции в Oracle - PullRequest
Новая
       48

Проверка существования элемента коллекции в Oracle

3 голосов
/ 28 августа 2009

Я создаю простой тип: 

create or replace TYPE SIMPLE_TYPE AS OBJECT (ID NUMBER(38), NAME VARCHAR2(20));

Простой тест: 

DECLARE
   TYPE ObjectList IS TABLE OF SIMPLE_TYPE;
   tmp SIMPLE_TYPE := SIMPLE_TYPE(1, 'a');
   o ObjectList := new ObjectList(SIMPLE_TYPE(2, 'a'), SIMPLE_TYPE(3, 'a'));
BEGIN
   IF tmp.EXISTS(tmp) THEN
    dbms_output.put_line('OK, exists.');
   END IF;
END;

Я получаю исключение: PLS-00302: должен быть объявлен компонент "EXISTS"

Но этот пример работы: 

DECLARE
   TYPE NumList IS TABLE OF INTEGER;
   n NumList := NumList(1,3,5,7);
BEGIN
   n.DELETE(2);
   IF n.EXISTS(1) THEN
      dbms_output.put_line('OK, element #1 exists.');
   END IF;
   IF n.EXISTS(3) = FALSE THEN
      dbms_output.put_line('OK, element #2 has been deleted.');
   END IF;
   IF n.EXISTS(99) = FALSE THEN
      dbms_output.put_line('OK, element #99 does not exist at all.');
   END IF;
END;

Можно ли реализовать метод EXISTS в типе SIMPLE_TYPE?

Ответы [ 2 ]

8 голосов
/ 30 августа 2009

Как указано в документации , EXISTS(), проверяется наличие пронумерованной записи в коллекции. То есть array.exists(3) утверждает, что третий элемент array заполнен.

В первом примере вы пытаетесь проверить, соответствует ли экземпляр tmp элементу в ObjectList. Начиная с 10g мы можем делать это, используя синтаксис MEMBER OF. К сожалению, для того, чтобы сделать эту работу, мы должны объявить метод MAP, который довольно неуклюжий и будет довольно раздражающим, если у объекта много атрибутов. 

SQL> create or replace type simple_type as object
  2       ( id number
  3         , name varchar2(30)
  4         , map member function compare return varchar2);
  5  /

Type created.

SQL>
SQL> create or replace type body simple_type as
  2       map member function compare return varchar2
  3       is
  4          return_value integer;
  5       begin
  6          return to_char(id, '0000000')||name;
  7       end compare;
  8  end;
  9  /

Type body created.

SQL>

Запуск примера ... 

SQL> set serveroutput on size unlimited
SQL>
SQL> declare
  2      type objectlist is table of simple_type;
  3      tmp simple_type := simple_type(1, 'a');
  4      o objectlist := new objectlist(simple_type(2, 'a'), simple_type(3, 'a'));
  5  begin
  6      if tmp MEMBER OF o then
  7          dbms_output.put_line('ok, exists.');
  8      else
  9          dbms_output.put_line('search me');
 10      end if;
 11  end;
 12  /
search me

PL/SQL procedure successfully completed.

SQL>
3 голосов
/ 28 августа 2009 
tmp SIMPLE_TYPEE := SIMPLE_TYPE(1, 'a');

…

IF tmp.EXISTS(tmp) THEN

Вы объявляете tmp как SIMPLE_TYPE, а не ObjectList.

SIMPLE_TYPE является скалярным типом, а не коллекцией.

Возможно, вы хотели проверить o.EXISTS вместо этого (что является ObjectList)?

Обновление:

EXISTS при применении к коллекции принимает целочисленный индекс в качестве аргумента и проверяет, существует ли элемент с этим индексом (не его значение).

Чтобы проверить, что SIMPLE_TYPE(1, 'a') существует в вашей таблице, вы должны сделать следующее:

Создать ObjectList в словаре: 

CREATE TYPE ObjectList IS TABLE OF SIMPLE_TYPE;

Выполните запрос SELECT: 

DECLARE
        tmp SIMPLE_TYPE := SIMPLE_TYPE(1, 'a');
        o ObjectList := new ObjectList(SIMPLE_TYPE(2, 'a'), SIMPLE_TYPE(3, 'a'));
        myid INT;
BEGIN
        SELECT  1
        INTO    myid
        FROM    TABLE(o) q
        WHERE   SIMPLE_TYPE(q.id, q.name) = tmp
                AND rownum = 1;
        IF (myid = 1) THEN
                dbms_output.put_line('OK, exists.');
        END IF;
END;
...