Читать значение один за другим с помощью VBScript

Question

У меня есть файл свойств, как показано ниже:

FileToRead=project.xml,CheckFile.ini
RunTimeFile=MyRuntime.xml

Я хочу прочитать значение параметра FileToRead через запятую по одному, используя цикл For VBScript.

Сценарий, который я пробовал для примера:

Set fso = CreateObject("Scripting.FileSystemObject")

Const ForReading = 1
Const ForWriting = 2

listFile = fso.OpenTextFile("MyFile.properties").ReadLine
listcheck = Split(listFile, vbCrLf)

For Each MyValue In listcheck
    segments = Split(line, ",")
    WScript.Echo "SimpleCheck" 
Next

И есть ли возможность использовать условие Or внутри If блока в VBS?

Answer 1

Вы можете использовать что-то вроде

Set fso = CreateObject("Scripting.FileSystemObject")

'Dictionary to store all the lines in form of key value pair
Set dict = CreateObject("Scripting.Dictionary")

Set file = fso.OpenTextFile ("<InputFilePath>", 1)

'Reading the file and storing properties in the dictionary
Do Until file.AtEndOfStream
  line = file.Readline
  splittedLine = Split(line,"=")
  if UBound(splittedLine)=1 then
    dict.Add splittedLine(0),splittedLine(1)
  end if
Loop
file.Close

'Now get the value from dictionary using key name FileToRead
valFileToRead = dict.item("FileToRead")
arrFiles=Split(valFileToRead,",")
for i=0 to UBound(arrFiles)
  'Do anything with the values
  msgBox(arrFiles(i))
next

Да, вы можете использовать ключевое слово OR внутри, если

if Condition1 OR Condition 2 then
   'Code
end if