Поиск элементов в разных узлах

Question

Это продолжение этого вопроса .

У меня есть следующий входной XML

<file>
    <data>
        <item>2</item>
        <item>4</item>
        <item>6</item>
        <item>7</item>
    </data>

    <names>
        <person><id>1</id><name>Anton</name></person>
        <person><id>2</id><name>Bruce</name></person>
        <person><id>3</id><name>Chris</name></person>
        <person><id>4</id><name>Dirk</name></person>
        <person><id>5</id><name>Erik</name></person>
        <person><id>6</id><name>Fred</name></person>
    </names>

    <morenames>
        <person><id>6</id><name>Ferdinand</name></person>
        <person><id>7</id><name>George</name></person>
    </morenames>
</file>

Этот XSLT покажет Bruce, Dirk, Fred

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
  <xsl:output method="text"/>
  <xsl:key name="pers-by-id" match="names/person" use="id"/>

  <xsl:template match="/">
      <xsl:apply-templates select="key('pers-by-id', file/data/item)/name"/>
  </xsl:template>

  <xsl:template match="name">
      <xsl:if test="position() > 1">, </xsl:if>
      <xsl:value-of select="."/>
  </xsl:template>
</xsl:stylesheet>

Кто-нибудь знает, как я могу изменить этот XSLT, чтобы он показывал Bruce, Dirk, Fred, George?Обратите внимание, что:

• элементы следует искать в <names> first
• , только если они не найдены в <names>, следует попытаться найти элемент в <morenames>
• Фердинанд никогда не должен показываться, потому что его <id> также появляется в <names>

Answer 1

Мое предложение об адаптации ответа https://stackoverflow.com/a/54959155/252228 будет

<xsl:stylesheet
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    version="1.0">

  <xsl:output method="text"/>

  <xsl:key name="pers-by-id" match="names/person" use="id"/>
  <xsl:key name="other-pers-by-id" match="morenames/person" use="id"/>

  <xsl:template match="/">
      <xsl:apply-templates 
        select="key('pers-by-id', file/data/item)/name | 
                key('other-pers-by-id', file/data/item[not(key('pers-by-id', .))])/name"/>
  </xsl:template>

  <xsl:template match="name">
      <xsl:if test="position() > 1">, </xsl:if>
      <xsl:value-of select="."/>
  </xsl:template>

</xsl:stylesheet>

https://xsltfiddle.liberty -development.net / ej9EGc4 / 2

Answer 2

Как насчет:

XSLT 1.0

<xsl:stylesheet version="1.0 "
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="text"/>

<xsl:key name="name-by-id" match="names/person" use="id"/>
<xsl:key name="alt-name-by-id" match="morenames/person" use="id"/>

<xsl:template match="/file">
    <xsl:for-each select="data/item">
        <xsl:variable name="name" select="key('name-by-id', .)" />
        <xsl:choose>
            <xsl:when test="$name">
                <xsl:value-of select="$name/name"/>
            </xsl:when>
            <xsl:otherwise>
                <xsl:value-of select="key('alt-name-by-id', .)/name"/>
            </xsl:otherwise>
        </xsl:choose>
        <xsl:if test="position()!=last()">, </xsl:if>
    </xsl:for-each>
</xsl:template>

</xsl:stylesheet>

---

Если names всегда предшествует morenames во входном XML, вы можете сократитьэто к:

<xsl:stylesheet version="1.0 "
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="text"/>

<xsl:key name="name-by-id" match="person" use="id"/>

<xsl:template match="/file">
    <xsl:for-each select="data/item">
        <xsl:value-of select="key('name-by-id', .)[1]/name"/>
        <xsl:if test="position()!=last()">, </xsl:if>
    </xsl:for-each>
</xsl:template>

</xsl:stylesheet>