Почему я получаю синтаксическую ошибку в моей программе, созданную с помощью flex и yacc? - PullRequest
Новая
       11

Почему я получаю синтаксическую ошибку в моей программе, созданную с помощью flex и yacc?

0 голосов
/ 17 ноября 2009

Я создал программу, которая должна распознавать простую грамматику. Когда я ввожу то, что я считаю правильным, я получаю сообщение об ошибке. В частности, если я наберу

int a;

int b;

это не работает. После того, как я ввожу int a; программа повторяет; по какой-то причине. Затем, когда я набираю int b; Я получаю синтаксическую ошибку.

Файл lex: 

%{
#include <stdlib.h>
#include <ctype.h>
#include <string.h>

#include "y.tab.h"

%}

else ELSE
if IF
int INT|int
return RETURN
void VOID
while WHILE
id [a-zA-Z]*
num [0-9]*
lte <=
gte >=
equal ==
notequal !=

%%

{else}  {   return ELSE; }
{if}    {   return IF; }
{int}   {   return INT; }
{return} {  return RETURN; }
{void} {    return VOID; }
{while} {   return WHILE; }
{id} {      return ID; }
{num} {     return NUM; }
{lte} {     return LTE; }
{gte} {     return GTE; }
{equal} {   return EQUAL; }
{notequal} {    return NOTEQUAL; }
%%

Файл yacc: 

/* C-Minus BNF Grammar */

%token ELSE
%token IF
%token INT
%token RETURN
%token VOID
%token WHILE

%token ID
%token NUM

%token LTE
%token GTE
%token EQUAL
%token NOTEQUAL
%%

program : declaration_list ;

declaration_list : declaration_list declaration | declaration ;

declaration : var_declaration | fun_declaration ;

var_declaration : type_specifier ID ';'
                | type_specifier ID '[' NUM ']' ';' ;

type_specifier : INT | VOID ;

fun_declaration : type_specifier ID '(' params ')' compound_stmt ;

params : param_list | VOID ;

param_list : param_list ',' param
           | param ;

param : type_specifier ID | type_specifier ID '[' ']' ;

compound_stmt : '{' local_declarations statement_list '}' ;

local_declarations : local_declarations var_declaration
                   | /* empty */ ;

statement_list : statement_list statement
               | /* empty */ ;

statement : expression_stmt
          | compound_stmt
          | selection_stmt
          | iteration_stmt
          | return_stmt ;

expression_stmt : expression ';'
                | ';' ;

selection_stmt : IF '(' expression ')' statement
               | IF '(' expression ')' statement ELSE statement ;

iteration_stmt : WHILE '(' expression ')' statement ;

return_stmt : RETURN ';' | RETURN expression ';' ;

expression : var '=' expression | simple_expression ;

var : ID | ID '[' expression ']' ;

simple_expression : additive_expression relop additive_expression
                  | additive_expression ;

relop : LTE | '<' | '>' | GTE | EQUAL | NOTEQUAL ;

additive_expression : additive_expression addop term | term ;

addop : '+' | '-' ;

term : term mulop factor | factor ;

mulop : '*' | '/' ;

factor : '(' expression ')' | var | call | NUM ;

call : ID '(' args ')' ;

args : arg_list | /* empty */ ;

arg_list : arg_list ',' expression | expression ;

Ответы [ 2 ]

1 голос
/ 17 ноября 2009

Lex: 

id [a-zA-Z]*
num [0-9]*

в обоих случаях могут встречаться пустые строки, вместо этого используйте '+'

1 голос
/ 17 ноября 2009

Хорошо ... вам нужно добавить точку с запятой в качестве токена в спецификации языка ... как к сведению, выполните поиск в Google по этому вопросу ... есть несколько файлов lex / yacc для C а также язык программирования ... и по этому поводу есть множество учебников ... flex / bison не прощают ошибок в спецификации программ ... вам действительно нужно понимать элементы того, как это работает ... Ищите Джека Креншоу знаменитый учебник о том, как собрать компилятор.

...