Как извлечь определенные строковые значения в многострочное событие

Question

Это мое многоплановое мероприятие.Все, что мне нужно сделать, это создать CSV-файл со значениями Timestamp, User, ecid и RemoteIP.Эти поля доступны в row1, row11, row14 и row16 в моем многопоточном событии.Я попытался использовать AWK и смог найти строки, начинающиеся с User, ecid и т. Д., И смог обрезать поле 2, используя

awk -F'[=:]' '/User|ecid|RemoteIP/{print NR ", " $2  }' filename.txt

, но мне нужно было узнать, как получить метку времени, которая находится в строке 1Также необходимо знать, как сделать так, чтобы эти 4 значения отображались в одной строке, разделенной каналом.Я ищу входные данные здесь в AWK или Perl

[2019-03-01T10:08:30.00] [OBIPS] [TRACE:1] [] [saw.httpserver.request.showrequest] [ecid: 90b8:1e:16:-800-000,0:9] [tid: 563620160] Request received.
Type: POST            Headers:
Connection=Keep-Alive
Content-Length=58
Cookie=ORA_BIPS_LBINFO=16938b9e78c
User-Agent=Mozilla/5.0 (Windows NT 10.0; WOW64) AppleWebKit/537.36 (KHTML, like Gecko) Chrome/64.0.3282.119 Safari/537.36
X-BlueCoat-Via=56038f342870633d
X-Forwarded-For=10.132.198.91
            Request params:
bieehome
icharset=utf-8
User=bi_admin
Password=******
SessionID: 9n5be88r2b041s5s6toojpagruk7ums
ecid: 90b8:1e:16:-800-000,0:9
ThreadID: 5636201600
RemoteIP: 10.192.121.136
]]

Ouptut

Timestamp | User | ecid | RemoteIP
2019-03-01T10:08:30.00 | bi_admin | 90b8:1e:16:-800-000,0:9 | 10.192.121.136

Answer 1

Используйте пробел или : (за которым следует пробел) или = или [ или ] в качестве разделителей полей (FS).OFS - это разделитель выходных полей.

awk 'BEGIN{FS=" |: |=|\\[|\\]"; OFS=" | "} 
     $5=="OBIPS"    {time=$2}
     $1=="User"     {user=$2}
     $1=="ecid"     {ecid=$2}
     $1=="RemoteIP" {ip=$2; print time,user,ecid,ip}' file

Выход:

2019-03-01T10:08:30.00 | bi_admin | 90b8:1e:16:-800-000,0:9 | 10.192.121.136

---

См .: 8 Мощные встроенные переменные Awk - FS, OFS, RS, ORS,NR, NF, FILENAME, FNR

Answer 2

Не могли бы вы попытаться выполнить следующие действия, в скором времени добавится также форма не одного лайнера с объяснением кода.

awk  '
BEGIN{
  OFS=" | "
  print "Timestamp | User | ecid | RemoteIP"
}
/^\]\]/{
  if(val){
      print val
  }
  val=""
}
/^\[[0-9]+\-[0-9]+\-[0-9]+/{
  gsub(/\]|\[|\..*/,"",$1)
  val=$1
  next
}
/User=/{
  sub(/.*User=/,"")
  val=val OFS $0
  next
}
/ecid/{
  sub(/.*: /,"")
  val=val OFS $0
  next
}
/RemoteIP/{
  sub(/.*: /,"")
  val=val OFS $0
}
END{
  if(val){
    print val
  }
}
'  Input_file

Вывод будет следующим.

Timestamp | User | ecid | RemoteIP
2019-03-01T10:08:30 | bi_admin | 90b8:1e:16:-800-000,0:9 | 10.192.121.136

Объяснение вышеуказанного кода:

awk  '                                                     ##Starting awk program here.
BEGIN{                                                     ##Starting BEGIN section from here.
  OFS=" | "                                                ##Setting OFS(output field separator) as space pipe space for all lines of Input_file.
  print "Timestamp | User | ecid | RemoteIP"               ##Printing header mentioned by OP in request here, will be printed before Input_file gets read.
}                                                          ##Closing BEGIN section of awk program here.
/^\]\]/{                                                   ##Checking condition if a line starts from ]] then do following.
  if(val){                                                 ##Checking condition if variable val value is NOT NULL then do following.
      print val                                            ##Printing variable val here.
  }                                                        ##Closing block for if condition here.
  val=""                                                   ##Nullifying variable val here.
}                                                          ##Closing BLOCK for]] condition.
/^\[[0-9]+\-[0-9]+\-[0-9]+/{                               ##Checking condition if a line starts from [ digits-digits-digits then do following.
  gsub(/\]|\[|\..*/,"",$1)                                 ##Globally substituting ] and [ from 1st field.
  val=$1                                                   ##Setting value of val as $1 here.
  next                                                     ##Skipping all statements from here.
}                                                          ##Closing BLOCK for ^[ condition now.
/User=/{                                                   ##Checking condition if a line contains User=then do following.
  sub(/.*User=/,"")                                        ##Substituting everything till User=
  val=val OFS $0                                           ##Concatenating value of $0 to val here.
  next                                                     ##next will skip all statements from here.
}
/ecid/{                                                    ##Checking condition if a line contains ecid then do following.
  sub(/.*: /,"")                                           ##Substituting everything till : space in line.
  val=val OFS $0                                           ##Concatenating value of $0 to val here.
  next                                                     ##next will skip all statements from here.
}
/RemoteIP/{                                                ##Checking condition if a line contains RemoteIP then do following.
  sub(/.*: /,"")                                           ##Substituting everything till : space in line.
  val=val OFS $0                                           ##Concatenating value of $0 to val here.
}
END{                                                       ##mentioning END section of this awk code, this will be executed once Input_file is done with reading.
  if(val){                                                 ##Checking if variable val is NOT NULL then do following.
    print val                                              ##Printing variable val here.
  }
}
' Input_file                                               ##Mentioning Input_file name here.