Объединение значений столбцов в список через запятую

Question

Что такое синтаксис TSQL для форматирования выходных данных, чтобы значения столбцов отображались в виде строки, разделенной запятыми.

Например, моя таблица CARS имеет следующее:

CarID    CarName  
----------------
    1    Porsche  
    2    Mercedes  
    3    Ferrari  

Как я могу получить названия автомобилей как: Porsche, Mercedes, Ferrari

Answer 1

SELECT LEFT(Car, LEN(Car) - 1)
FROM (
    SELECT Car + ', '
    FROM Cars
    FOR XML PATH ('')
  ) c (Car)

Answer 2

Вы можете сделать ярлык, используя coalesce, чтобы объединить ряд строк из записи в таблице, например.

declare @aa varchar (200)
set @aa = ''

select @aa = 
    case when @aa = ''
    then CarName
    else @aa + coalesce(',' + CarName, '')
    end
  from Cars

print @aa

Answer 3

Вы можете сделать это, используя вещи:

SELECT Stuff(
    (
    SELECT ', ' + CARS.CarName
    FROM CARS
    FOR XML PATH('')
    ), 1, 2, '') AS CarNames

Answer 4

Если вы работаете в SQL Server 2017 или базе данных SQL Azure, вы делаете что-то вроде этого:

 SELECT STRING_AGG(CarName,',') as CarNames
 FROM CARS 

Answer 5

Другое решение в запросе:

select 
    Id, 
    STUFF(
        (select (', "' + od.ProductName + '"')
        from OrderDetails od (nolock)
        where od.Order_Id = o.Id
        order by od.ProductName
        FOR XML PATH('')), 1, 2, ''
    ) ProductNames
from Orders o (nolock)
where o.Customer_Id = 525188
order by o.Id desc

(РЕДАКТИРОВАТЬ: спасибо @ user007 за объявление STUFF)

Answer 6

DECLARE @CarList nvarchar(max);
SET @CarList = N'';
SELECT @CarList+=CarName+N','
FROM dbo.CARS;
SELECT LEFT(@CarList,LEN(@CarList)-1);

Спасибо всем, кто в SO показал мне использование накопления данных во время запроса.

Answer 7

Пожалуйста, попробуйте это с помощью следующего кода:

DECLARE @listStr VARCHAR(MAX)
SELECT @listStr = COALESCE(@listStr+',' , '') + CarName
FROM Cars
SELECT @listStr

Answer 8

 DECLARE @SQL AS VARCHAR(8000)
SELECT @SQL = ISNULL(@SQL+',','') + ColumnName FROM TableName
SELECT @SQL