Поиск данных во всех существующих таблицах базы данных

Question

Я хочу найти дату '2017-08-08 09:26' во всех существующих таблицах базы данных и получить имя столбца и имя таблицы, содержащей эту дату.Поэтому я могу найти эту дату в таблице A в столбце a.

пример: «2017-08-08 09:26» существует в столбце «a» таблицы «A»

Пожалуйста, дайтемне несколько предложений для решения.

Сейчас я использую этот запрос, в котором я могу искать столбцы, но я хочу искать данные в столбцах таблиц в моей базе данных.

SELECT   
  sys.columns.name AS ColumnName,
  sys.tables.name AS TableName    
FROM
  sys.columns
JOIN    
  sys.tables   
ON    
  sys.columns.object_id = sys.tables.object_id    
WHERE   
  sys.columns.name LIKE '%service%'

Answer 1

Используйте приведенный ниже скрипт для получения полного поиска в БД

DECLARE
@SearchStr nvarchar(100) = 'Pass'

BEGIN

DECLARE @Results TABLE(ColumnName nvarchar(370), ColumnValue nvarchar(3630))

SET NOCOUNT ON

DECLARE @TableName nvarchar(256), @ColumnName nvarchar(128), @SearchStr2 varchar(110)
SET  @TableName = ''
SET @SearchStr2 = QUOTENAME('%' + @SearchStr + '%','''')

WHILE @TableName IS NOT NULL
BEGIN
   SET @ColumnName = ''
   SET @TableName = 
   (
    SELECT MIN(QUOTENAME(TABLE_SCHEMA) + '.' + QUOTENAME(TABLE_NAME))
    FROM    INFORMATION_SCHEMA.TABLES
    WHERE       TABLE_TYPE = 'BASE TABLE'
        AND QUOTENAME(TABLE_SCHEMA) + '.' + QUOTENAME(TABLE_NAME) > @TableName
        AND OBJECTPROPERTY(
                OBJECT_ID(
                    QUOTENAME(TABLE_SCHEMA) + '.' + QUOTENAME(TABLE_NAME)
                     ), 'IsMSShipped'
                       ) = 0
)

WHILE (@TableName IS NOT NULL) AND (@ColumnName IS NOT NULL)
BEGIN
    SET @ColumnName =
    (
        SELECT MIN(QUOTENAME(COLUMN_NAME))
        FROM    INFORMATION_SCHEMA.COLUMNS
        WHERE       TABLE_SCHEMA    = PARSENAME(@TableName, 2)
            AND TABLE_NAME  = PARSENAME(@TableName, 1)
            AND DATA_TYPE IN ('char', 'varchar', 'nchar', 'nvarchar')
            AND QUOTENAME(COLUMN_NAME) > @ColumnName
    )

    IF @ColumnName IS NOT NULL
    BEGIN
        INSERT INTO @Results
        EXEC
        (
            'SELECT ''' + @TableName + '.' + @ColumnName + ''', LEFT(' + @ColumnName + ', 3630) 
            FROM ' + @TableName + ' (NOLOCK) ' +
            ' WHERE ' + @ColumnName + ' LIKE ' + @SearchStr2
        )
    END
END 
END

SELECT ColumnName, ColumnValue FROM @Results
END

Answer 2

Для этого вам понадобится старый добрый динамический SQL:

DECLARE @Sql varchar(max);
SELECT @Sql = STUFF((SELECT 'UNION ALL ' + CHAR(10) +'SELECT '''+ 
  sys.columns.name +''' AS ColumnName, '''+ 
  sys.tables.name +''' AS TableName '+ CHAR(10) +
  'FROM sys.tables.name ' + CHAR(10) +
  'WHERE '+ QUOTENAME(sys.columns.name) +' = @DateTimeValue ' + CHAR(10)

FROM
  sys.columns
JOIN    
  sys.tables     
ON    
  sys.columns.object_id = sys.tables.object_id    
-- type ids:  datetime2, smalldatetime, datetime 
WHERE sys.columns.system_type_id IN(42, 58, 61)
FOR XML PATH('')
), 1, 11, 'DECLARE @DateTimeValue datetime = ''2017-08-08T09:26:00'';' + CHAR(10))

-- When using dynamic SQL, PRINT is your best friend.
PRINT @Sql

/*
@Sql should contain something like this:

DECLARE @DateTimeValue datetime = '2017-08-08T09:26:00';
SELECT 'Col1' AS ColumnName, 'Table1' AS TableName 
FROM sys.tables.name 
WHERE [Col1] = @DateTimeValue 
UNION ALL 
SELECT 'Col2' AS ColumnName, 'Table12' AS TableName 
FROM sys.tables.name 
WHERE [Col2] = @DateTimeValue 
...

 */

-- Unremark only after you've seen what's inside @Sql.
--EXEC(@Sql)