Тестовая настройка между тестированием на основе данных

Question

Я создал несколько тестовых случаев, используя тестирование на основе данных.

Но при присоединении Test Setup / Teardown к разделу Setting настройка и разбор выполняются до и послетестирование всех наборов данных.

Робот

*** Settings ***
Test Setup  setup
Test Teardown  teardown

*** Keywords ***

Test Case Should Pass
    [Arguments]  ${arg1}  ${arg2}  ${arg3}
    something "${arg1}"
    something "${arg2}"
    something "${arg3}"

something "${arg}"
    Log To Console  ${arg}

setup
    Log To Console  setup

teardown
    Log To Console  teardown

*** Test Case ***

Test Case
    [Template]  Test Case Should Pass
    a1  a2  a3
    b1  b2  b3

Фактический

==============================================================================
Something
==============================================================================
Test Case                                                             setup
.a1
a2
a3
.b1
b2
b3
.teardown
Test Case                                                             | PASS |
------------------------------------------------------------------------------
Something                                                             | PASS |
1 critical test, 1 passed, 0 failed
1 test total, 1 passed, 0 failed
==============================================================================

Ожидаемый

==============================================================================
Something
==============================================================================
Test Case                                                             setup
.a1
a2
a3
teardown
setup
.b1
b2
b3
.teardown
Test Case                                                             | PASS |
------------------------------------------------------------------------------
Something                                                             | PASS |
1 critical test, 1 passed, 0 failed
1 test total, 1 passed, 0 failed
==============================================================================

Есть ли способ, которым я могуSetup / Teardown должен выполняться между каждым проверенным набором данных?

Answer 1

Это будет работать:

*** Settings ***
Test Setup  setup
Test Teardown  teardown
Test Template  Test Case Should Pass

*** Keywords ***

Test Case Should Pass
    [Arguments]  ${arg1}  ${arg2}  ${arg3}
    something "${arg1}"
    something "${arg2}"
    something "${arg3}"

something "${arg}"
    Log To Console  ${arg}

setup
    Log To Console  setup

teardown
    Log To Console  teardown

*** Test Case ***
A
    a1  a2  a3
B
    b1  b2  b3