Не удалось получить неизвестное свойство 'android' для корневого проекта 'FirebaseExample' типа org.gradle.api.Project

Question

Я обновился до Android Studio 3.5 и попытался использовать зависимость «One Signal», но Gradle не синхронизируется.Я пытался обновить Gradle, но, похоже, последняя версия уже использовалась.

build.gradle (корневой проект):

apply plugin: 'com.onesignal.androidsdk.onesignal-gradle-plugin'

buildscript {
    repositories {
        google()
        jcenter()
        maven { url 'https://plugins.gradle.org/m2/'}   
    }

    dependencies {
        classpath 'com.android.tools.build:gradle:3.5.0'
        classpath 'com.google.gms:google-services:4.3.2'
        classpath 'gradle.plugin.com.onesignal:onesignal-gradle-plugin:[0.12.4, 0.99.99]'
    }
}

allprojects {
    repositories {
        maven { url 'https://maven.google.com' }
        google()
        jcenter()  
    }
}

build.gradle (модуль :app):

apply plugin: 'com.android.application'

android {
    compileSdkVersion 29
    buildToolsVersion "29.0.2"
    defaultConfig {
        applicationId "com.admin.firebaseexample"
        minSdkVersion 16
        targetSdkVersion 29
        versionCode 1
        versionName "1.0"
        testInstrumentationRunner "androidx.test.runner.AndroidJUnitRunner"
    }

    buildTypes {
        release {
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android-optimize.txt'), 'proguard-rules.pro'
        }
    }
}

dependencies {
    implementation fileTree(dir: 'libs', include: ['*.jar'])
    implementation 'androidx.appcompat:appcompat:1.1.0'
    implementation 'androidx.constraintlayout:constraintlayout:1.1.3'
    implementation 'com.google.firebase:firebase-analytics:17.2.0'
    implementation 'com.google.firebase:firebase-inappmessaging-display:19.0.1'
    implementation 'com.onesignal:OneSignal:3.11.4'

    testImplementation 'junit:junit:4.12'
    androidTestImplementation 'androidx.test:runner:1.2.0'
    androidTestImplementation 'androidx.test.espresso:espresso-core:3.2.0'
}
apply plugin: 'com.google.gms.google-services'

Мне нужна успешная сборка, чтобы продолжить работу с моим приложением.

Answer 1

Попробуйте переместить эту строку из корневого проекта build.gradle:

apply plugin: 'com.onesignal.androidsdk.onesignal-gradle-plugin'

в модуль :app build.gradle:

apply plugin: 'com.android.application'
apply plugin: 'com.onesignal.androidsdk.onesignal-gradle-plugin'