Основы F #: складывание 2 списков в строку - PullRequest
Новая
       20

Основы F #: складывание 2 списков в строку

5 голосов
/ 23 декабря 2009

немного ржавый из моих дней Scheme, я хотел бы взять 2 списка: один из чисел и один из строк, и сложить их в одну строку, где каждая пара написана как "{(ushort) 5," бла бла бла "}, \ n". У меня есть большая часть, я просто не уверен, как правильно написать фолд: 

let splitter = [|","|]
let indexes = 
  indexStr.Split(splitter, System.StringSplitOptions.None) |> Seq.toList 
let values = 
  valueStr.Split(splitter, System.StringSplitOptions.None) |> Seq.toList

let pairs = List.zip indexes values
printfn "%A" pairs

let result = pairs |> Seq.fold
    (fun acc a -> String.Format("{0}, \{(ushort){1}, \"{2}\"\}\n", 
                                acc, (List.nth a 0), (List.nth a 1)))

Ответы [ 5 ]

10 голосов
/ 23 декабря 2009

Вам не хватает двух вещей. Начальное состояние сгиба - пустая строка, и вы не можете использовать списки в кортежах в F #. 

let splitter = [|","|]
let indexes = 
    indexStr.Split(splitter, System.StringSplitOptions.None) |> Seq.toList 
let values = 
    valueStr.Split(splitter, System.StringSplitOptions.None) |> Seq.toList

let pairs = List.zip indexes values
printfn "%A" pairs

let result = 
    pairs 
    |> Seq.fold (fun acc (index, value) -> 
        String.Format("{0}{{(ushort){1}, \"{2}\"}},\n", acc, index, value)) ""

fold2 версия 

let result = 
    List.fold2 
        (fun acc index value -> 
            String.Format("{0}{{(ushort){1}, \"{2}\"}},\n", acc, index, value))
        "" 
        indexes 
        values

Если вас беспокоит скорость, вы можете использовать построитель строк, поскольку он не создает новую строку каждый раз, когда вы добавляете. 

let result = 
    List.fold2 
        (fun (sb:StringBuilder) index value -> 
            sb.AppendFormat("{{(ushort){0}, \"{1}\"}},\n", index, value)) 
        (StringBuilder()) 
        indexes 
        values
    |> string
8 голосов
/ 23 декабря 2009

Fold, вероятно, не лучший метод для этой задачи. Намного проще отобразить и сопоставить так: 

let l1 = "a,b,c,d,e".Split([|','|])
let l2 = "1,2,3,4,5".Split([|','|])
let pairs =
    Seq.zip l1 l2
    |> Seq.map (fun (x, y) -> sprintf "(ushort)%s, \"%s\"" x y)
    |> String.concat "\n"
1 голос
/ 23 декабря 2009

Я думаю, что вы хотите List.fold2. По какой-то причине модуль List имеет член fold2, а Seq - нет. Тогда вы можете полностью отказаться от zip.

Типы ваших именованных переменных и тип результата, на который вы надеетесь, неявны, поэтому сложно помочь, но если вы пытаетесь собрать список строк, вы можете рассмотреть что-то вроде 

let result = pairs |> Seq.fold
  (fun prev (l, r) -> 
          String.Format("{0}, \{(ushort){1}, \"{2}\"\}\n", prev, l, r) 
  "" pairs

Мой F # / Caml очень ржавый, поэтому у меня может быть неправильный порядок аргументов. Также обратите внимание, что ваше строение строки квадратично; в моем собственном коде я хотел бы пойти с чем-то еще по этим направлениям: 

let strings = 
   List.fold2 (fun ss l r -> 
                 String.format ("\{(ushort){0}, \"{1}\"\}\n", l, r) :: ss)
              [] indexes values

let result = String.concat ", " strings

Это не будет стоить вам квадратичного времени, и за ним будет немного легче следить. Я проверил MSDN и считаю, что у меня есть правильный порядок аргументов на fold2.

Имейте в виду, я знаю, что Caml не F #, и поэтому у меня могут быть неправильные детали или порядок аргументов.

0 голосов
/ 29 декабря 2009

map2 или fold2 - правильный путь. Вот мой пример использования оператора (||>): 

let l1 = [| "a"; "b"; "c"; "d"; "e" |]
let l2 = [| "1"; "2"; "3"; "4"; "5" |]
let pairs = (l1, l2) ||> Seq.map2 (sprintf ("(ushort)%s, \"%s\""))
                      |> String.concat "\n"
0 голосов
/ 25 декабря 2009

Возможно, это: 

let strBuilder = new StringBuilder()
for (i,v) in Seq.zip indexes values do
     strBuilder.Append(String.Format("{{(ushort){0}, \"{1}\"}},\n", i,v))
     |> ignore

с F # иногда лучше идти срочно ...

...