Сохранение результатов запроса в csv

Question

Мне интересно, возможно ли сохранить результаты запроса в csv? Без создания представлений.

У меня большая таблица, но мне нужно только 2 столбца для обработки с python. Может быть, кто-то может помочь с этим?

Answer 1

Вот три способа

ODS

Запрос SQL может быть выведен в пункт назначения ODS CSV. Этот подход включает в себя самые широкие возможности запроса.

ods csv file='c:\temp\query-results.csv';

proc sql;
  select name, age 
  from sashelp.class
  where name like 'J%'
  ;
quit;

ods csv close;

EXPORT Процедура

Где можно применить предложение , используя сохраненные столбцы из 'большогоtable '(data=)

proc export 
  data = sashelp.class(
    keep=name age
    where = (
      name like 'J%'
    )
  ) 
  replace 
  file = 'c:\temp\class-subset.csv'
  dbms = csv
  ;
run;

DATA _null_

Где оператор может быть применен с использованием любых столбцов «большой таблицы»(SET). Оператор PUT определяет, какие столбцы выводятся.

data _null_;
  set sashelp.class;
  where name like 'J%';

  file 'c:\temp\subset-per-datastep.csv' dlm=',' dsd;

  if _n_ = 1 then put 'name,age';
  put name age;
run;

Answer 2

Я думаю, вы можете использовать ods для создания файла с результатами, например:

ods csv file="C:\test.csv" options(delimiter=';');

proc sql;
   select * from sashelp.class;
quit;

ods csv close;