Чтобы найти минимальное и максимальное соответствующее значение между диапазоном клубных значений

Question

У меня небольшая проблема с написанием формулы. У меня есть мои данные в этом формате:

NAME  |  EXP     |     SALARY

A     |  0.3     |      40000

B     |  4.7     |     490000

C     |  2.6     |     220000

D     |  3.9     |      34000

E     |  1.3     |     150000

F     |  3.2     |     300000

G     |  0.8     |      90000

H     |  1.9     |     170000

I     |  2.1     |     260000

J     |  4.1     |     390000

это то, что я хочу в своем выводе:

EXP-RANGE  | MIN SALARY  |  MAX SALARY

0-1

1-2

2-3

3-4

4-5

я хочу найти минимальную и максимальную зарплату людей в диапазоне опытая попытался использовать MIN (IF (<&>)), но он возвращает #VALUE?

Я также могу поместить все эти данные в базу данных и запросить их, но я был бы очень признателен всем, кто мог бы сформулировать их так, чтобыя могу работать на сам Excel. Размер данных 20000+, поэтому я бы не предпочел фильтры

Заранее спасибо

Answer 1

Предположим, что «Таблица поиска» вставлена ​​в A1:C11

Критерии с заголовком в G1:G6

В H2 (минимальная заработная плата), формула скопирована прямо на I2 (Макс. wage) и все скопировано вниз:

=AGGREGATE(14+(COLUMN(A1)=1),6,$C$2:$C$11/($B$2:$B$11>=IMREAL($G2&"i"))/($B$2:$B$11<-IMAGINARY($G2&"i")),1)

Редактировать: При преобразовании критерия "0-1" в комплексное число "0-1i" IMREAL () извлекает номер левой стороны "0"и IMAGINARY () извлекает номер правой стороны "1"

= AGGREGATE (14+(COLUMN(A1)=1), 6, ..., возврат в столбец K = AGGREGATE (15, 6,….)и столбец L = AGGREGATE (14, 6,….)

Answer 2

Используйте MAXIFS и MINIFS:

=MINIFS(C:C,B:B,">="&LEFT(G2,FIND("-",G2)-1),B:B,"<"&MID(G2,FIND("-",G2)+1,LEN(G2)))
=MAXIFS(C:C,B:B,">="&LEFT(G2,FIND("-",G2)-1),B:B,"<"&MID(G2,FIND("-",G2)+1,LEN(G2)))

---

Если у вас нет MAXIFS или MINIFS, мы можем использовать AGGREGATE:

=AGGREGATE(15,7,$C$2:$C$11/(($B$2:$B$11>=--LEFT(G2,FIND("-",G2)-1))*($B$2:$B$11<--MID(G2,FIND("-",G2)+1,LEN(G2)))),1)
=AGGREGATE(14,7,$C$2:$C$11/(($B$2:$B$11>=--LEFT(G2,FIND("-",G2)-1))*($B$2:$B$11<--MID(G2,FIND("-",G2)+1,LEN(G2)))),1)

AGGREGATE - формула типа массива, и ссылки должны быть ограничены набором данных.