Как оценить значение ячейки в той же ячейке

Question

Я пытаюсь ранжировать набор чисел (в столбце), но я хочу, чтобы этот ранг отображался рядом с номером в той же ячейке.

Например, если число равно «21»и это оценивает "3-й" - я хотел бы, чтобы ячейка читала "21 (3)". БОНУСНЫЕ ТОЧКИ, если я могу отформатировать (3), чтобы он был меньше / верхний индекс.

---

ЧТО Я ПРОБОВАЛ: Пока я работаю в ячейкев нем уже есть уравнение, я его упросту. Допустим, A23 = 15 и A24 = 6 . Я пробовал следующее уравнение, но оно продолжает давать мне ошибку. Я работаю в ячейке H103. Диапазон ранжирования: H103: H114.

=SUM(A23+A24) & "(" & RANK(H103,$H$103:$H$114) & ")"

Даже если я немного уберу скобки или переделываю это, у меня все равно останется ошибка. Просто пытаясь найти какой-либо способ, я могу получить 2 формулы с разными результатами в одной и той же ячейке;один из которых показывает ранг этой конкретной ячейки.

ЗДЕСЬ КОПИЯ НА МОЙ ЛИСТ - это дублированный лист Google, поэтому не стесняйтесь поиграть втам, если хотите. Я сосредоточен на рейтинге H103: H114.

Answer 1

вставьте в ячейку H103 :

=ARRAYFORMULA(TEXT(VLOOKUP(B103:B114, QUERY(INDIRECT($A$100&"!B:C"), 
 "select B,sum(C) where B is not null group by B", 0), 2, 0)+
 VLOOKUP(B103:B114, QUERY(INDIRECT($A$100&"!E:D"), 
 "select E,sum(D) where E is not null group by E", 0), 2, 0), "#.00")&" "&CHAR(8317)&
 VLOOKUP(RANK(VLOOKUP(B103:B114, QUERY(INDIRECT($A$100&"!B:C"), 
 "select B,sum(C) where B is not null group by B", 0), 2, 0)+
 VLOOKUP(B103:B114, QUERY(INDIRECT($A$100&"!E:D"), 
 "select E,sum(D) where E is not null group by E", 0), 2, 0), 
 VLOOKUP(B103:B114, QUERY(INDIRECT($A$100&"!B:C"), 
 "select B,sum(C) where B is not null group by B", 0), 2, 0)+
 VLOOKUP(B103:B114, QUERY(INDIRECT($A$100&"!E:D"), 
 "select E,sum(D) where E is not null group by E", 0), 2, 0), 0),  
 {1,  CHAR(185);             2, CHAR(178);            3, CHAR(179);  
  4,  CHAR(8308);            5, CHAR(8309);           6, CHAR(8310);           
  7,  CHAR(8311);            8, CHAR(8312);           9, CHAR(8313); 
  10, CHAR(185)&CHAR(8304); 11, CHAR(185)&CHAR(185); 12, CHAR(185)&CHAR(178)}, 2, 0)&
 CHAR(8318))

---

вставьте в ячейку I103 :

=ARRAYFORMULA(VLOOKUP(B103:B114, QUERY(INDIRECT($A$100&"!B:C"), 
 "select B,sum(C) where B is not null group by B", 0), 2, 0)+
 VLOOKUP(B103:B114, QUERY(INDIRECT($A$100&"!E:D"), 
 "select E,sum(D) where E is not null group by E", 0), 2, 0)-C103:C114)

---

вставка в ячейку L103 :

=ARRAYFORMULA(VLOOKUP(B103:B114, QUERY(INDIRECT($A$100&"!B:C"), 
 "select B,sum(C) where B is not null group by B", 0), 2, 0)+
 VLOOKUP(B103:B114, QUERY(INDIRECT($A$100&"!E:D"), 
 "select E,sum(D) where E is not null group by E", 0), 2, 0)-J103:J114)

---

условное форматирование для H столбца:

красный цветовая формула:

=REGEXMATCH(H103, CHAR(8317)&CHAR(185)&CHAR(178)&CHAR(8318))

зеленый цветовая формула:

=REGEXMATCH(H103, CHAR(8317)&CHAR(185)&CHAR(8318))