Как объявить массив с макросами в скрипте Lauterbach CMM - PullRequest
Новая
       51

Как объявить массив с макросами в скрипте Lauterbach CMM

0 голосов
/ 05 ноября 2019

Я хотел бы создать массив с макросами в скрипте Lauterbach CMM.

Можете ли вы помочь мне, как я могу это сделать? 

LOCAL &ARRAY_VAR[10]

Вышеприведенное утверждение не работает.

Я знаю, что создать массив с помощью Var.NEWLOCAL: 

Var.NEWLOCAL int[3] \ARRAY_VAR

Есть ли способ создать макрос с массивом?

1 Ответ

0 голосов
/ 08 ноября 2019

Короткий ответ : PRACTICE не поддерживает макро-массивы.

Более длинный ответ : PRACTICE может выполнять рекурсивное расширение макроса, что позволяет вамнечто похожее на реальные массивы. (См. «Макросы ПРАКТИКИ» в practice_user.pdf )

Например: 

LOCAL &myarr0 &myarr1 &myarr2 &myarr3   
LOCAL &data &i

&data="zero|one|two|three"

// Assign values to &myarra0 to &myarra3 in a loop
&i=0.
WHILE &i<4.
(
    PRIVATE &cmd
    &cmd="&"+"myarr"+FORMAT.Decimal(1,&i)+"=STRing.SPLIT(""&"+"data"",""|"",&i)"
    &&cmd   // << evaluate with recursive macro expansion
    &i=&i+1.
)

// Print values saved in &myarra0 to &myarra3 in a loop
&i=0.
WHILE &i<4.
(
    PRIVATE &val
    &val="&"+"myarr"+FORMAT.Decimal(1,&i)
    &&val="&val"   // << assign with recursive macro expansion
    ECHO "&val"
    &i=&i+1.
)

Если вам не нужно иметь слишком много макросов GLOBAL, вы также можете создатьпсевдомассив в цикле, подобный следующему: 

LOCAL &i
&i=0
WHILE &i<4.
(
    PRIVATE &cmd
    &cmd="GLOBAL "+"&"+"myarr"+FORMAT.Decimal(1,&i)
    &cmd
    &i=&i+1
)

Я бы этого не делал, потому что мне не нравятся глобальные макросы.

Обходной путь : Создать массив с помощью Var.NEWLOCAL

Например: 

Var.NEWLOCAL char[4][32] \myarr
LOCAL &i &data

&data="zero|one|two|three"

// Assign values to \myarr in a loop
&i=0.
WHILE &i<4
(
    PRIVATE &val
    &val=STRing.SPLIT("&data","|",&i)
    Var.Assign \myarr[&i]="&val"
    &i=&i+1.
)

// Print values saved in \myarr in a loop
&i=0.
WHILE &i<4
(
    ECHO Var.STRing(\myarr[&i])
    &i=&i+1.
)
...