Как напечатать только заполненные строки с диапазоном в почту | excel |УВА |

Question

Поскольку данные генерируются из базы данных с использованием SQL

Я хочу отобразить определенную строку данных, которые заполняются в диапазоне

Поскольку данные извлекаются из базы данных динамически, данные могутменяются каждый раз, когда я генерирую

пример: - ниже данные, полученные из базы данных, могут содержать несколько пустых строк

[Данные] [1]: https://i.stack.imgur.com/ysV64.png

Таким образом, проблема заключается в том, как определить в диапазоне, сколько строк заполнено, только те строки должны отображаться в теле письма (диапазон: A2: D16)

Мой код

Private Sub Mail_0_Click()
'Working in Excel 2000-2016
    Dim rng As Range
    Dim OutApp As Object
    Dim OutMail As Object

    Set rng = Nothing
    On Error Resume Next
    'Only the visible cells in the selection
    Set rng = Selection.SpecialCells(xlCellTypeVisible)
    'You can also use a fixed range if you want
    Set rng = Sheets("Sheet").Range("A2:D16").SpecialCells(xlCellTypeVisible)
    On Error GoTo 0

    If rng Is Nothing Then
        MsgBox "The selection is not a range or the sheet is protected" & _
               vbNewLine & "please correct and try again.", vbOKOnly
        Exit Sub
    End If

    With Application
        .EnableEvents = False
        .ScreenUpdating = False
    End With

    Set OutApp = CreateObject("Outlook.Application")
    Set OutMail = OutApp.CreateItem(0)

    On Error Resume Next
    With OutMail
        .To = "example@.com"
        .CC = ""
        .BCC = ""
        .Subject = "Student Details"
        ''.HTMLBody = RangetoHTML(rng)
        .HTMLBody = "Hi," _
         & vbNewLine & vbNewLine & _
         "Please find your details " & _
         RangetoHTML(rng)
        .Send   'or use .Display
    End With
    On Error GoTo 0

    With Application
        .EnableEvents = True
        .ScreenUpdating = True
    End With

    Set OutMail = Nothing
    Set OutApp = Nothing
End Sub


Function RangetoHTML(rng As Range)
    Dim fso As Object
    Dim ts As Object
    Dim TempFile As String
    Dim TempWB As Workbook

    TempFile = Environ$("temp") & "\" & Format(Now, "dd-mm-yy h-mm-ss") & ".htm"

    'Copy the range and create a new workbook to past the data in
    rng.Copy
    Set TempWB = Workbooks.Add(1)
    With TempWB.Sheets(1)
        .Cells(1).PasteSpecial Paste:=8
        .Cells(1).PasteSpecial xlPasteValues, , False, False
        .Cells(1).PasteSpecial xlPasteFormats, , False, False
        .Cells(1).Select
        Application.CutCopyMode = False
        On Error Resume Next
        .DrawingObjects.Visible = True
        .DrawingObjects.Delete
        On Error GoTo 0
    End With

    'Publish the sheet to a htm file
    With TempWB.PublishObjects.Add( _
         SourceType:=xlSourceRange, _
         Filename:=TempFile, _
         Sheet:=TempWB.Sheets(1).Name, _
         Source:=TempWB.Sheets(1).UsedRange.Address, _
         HtmlType:=xlHtmlStatic)
        .Publish (True)
    End With

    'Read all data from the htm file into RangetoHTML
    Set fso = CreateObject("Scripting.FileSystemObject")
    Set ts = fso.GetFile(TempFile).OpenAsTextStream(1, -2)
    RangetoHTML = ts.readall
    ts.Close
    RangetoHTML = Replace(RangetoHTML, "align=center x:publishsource=", _
                          "align=left x:publishsource=")

    'Close TempWB
    TempWB.Close savechanges:=False

    'Delete the htm file we used in this function
    Kill TempFile

    Set ts = Nothing
    Set fso = Nothing
    Set TempWB = Nothing

End Function

Вывод должен быть: только заполненные строки в пределах диапазона в теле письма, как показано ниже

[Вывод] [1]: https://i.stack.imgur.com/oqSLJ.png

Answer 1

Приведенный ниже цикл проходит по всем строкам в вашем диапазоне и определяет, есть ли какие-либо значения в строке. Затем он устанавливает диапазон, включающий все строки с данными.

Sub rngsel()
Dim rng As Range, cel As Range

For Each cel In Sheets("Sheet1").Range("A2:A16") 'loop over the first column in your range

    If Not Application.CountA(Range("A" & cel.Row & ":D" & cel.Row)) = 0 Then 'test if the entire row for each cell has any values with countif

        If rng Is Nothing Then  'test if this is the first row with values
            Set rng = Range("A" & cel.Row & ":D" & cel.Row) 'set the first row in the range
                        Else
                Set rng = Union(rng, Range("A" & cel.Row & ":D" & cel.Row)) 'add the found row to the already defined range

        End If

    End If

Next cel
End Sub