найти максимум чисел в z3 с помощью SMTLIB2 - PullRequest
Новая
       72

найти максимум чисел в z3 с помощью SMTLIB2

1 голос
/ 17 октября 2019

У меня есть 7 чашек, в которых содержится немного воды. Мне нужно запрограммировать эти чашки на разное количество воды. Как только это будет сделано, мне нужно измерить чашку с наибольшим количеством воды, а затем удалить некоторое количество (скажем, 2 единицы).

c реализаций: 

float c1=2.0, c2= 2.6, c3 = 2.8, c4=4.4 , c5 = 2.4, c6 = 2.1, c7 = 5.8;

if((c1 > c2) && (c1 > c3) && (c1 > c4) && (c1 > c5) && (c1 > c6) && (c1 > c7)); c1=c1-2;

if((c2 > c1) && (c2 > c3) && (c2 > c4) && (c2 > c5) && (c2 > c6) && (c2 > c7)); c2=c2-2;

if((c3 > c2) && (c3 > c1) && (c3 > c4) && (c3 > c5) && (c3 > c6) && (c3 > c7)); c3=c3-2;

if((c4 > c2) && (c4 > c3) && (c4 > c1) && (c4 > c5) && (c4 > c6) && (c4 > c7)); c4=c4-2;

if((c5 > c2) && (c5 > c3) && (c5 > c4) && (c5 > c1) && (c5 > c6) && (c5 > c7)); c5=c5-2;

if((c6 > c2) && (c6 > c3) && (c6 > c4) && (c6 > c5) && (c6 > c1) && (c6 > c7)); c6=c6-2;

if((c7 > c2) && (c7 > c3) && (c7 > c4) && (c7 > c5) && (c7 > c6) && (c7 > c1)); c7=c7-2;

Это даст ответ как c7 = 3.8

Я пытался реализовать это в z3 и назначил значения для c1 .. ..c7 

ite( (and((> c1  c2) (> c1  c3) (> c1  c4) (> c1  c5) (> c1  c6) (> c1  c7)))  (= c1_1 (- c1 2)  (= c1_1 c1))
.
.
.repeated till c7_1

и когда я получу значения модели, она должна дать c7_1 как 3.8

Можно ли определить это в z3? Когда я использую и различных условий в условии if (в ите), это дает мне ошибку. Разве это не может быть определено так? Есть ли что-нибудь в этом роде?

Заранее спасибо

[описание проблемы] [1]

Я экспериментирую с инструментом Z3, мне было легко получить первую частьОднако для второй части это немного сложно.

Ответы [ 2 ]

1 голос
/ 17 октября 2019

Вот альтернативный подход для поиска max, который не использует ITE. 

; declare the cups
(declare-const c1 Real)
(declare-const c2 Real)
(declare-const c3 Real)
(declare-const c4 Real)
(declare-const c5 Real)
(declare-const c6 Real)
(declare-const c7 Real)

; each cup has a non-negative units of water
(assert (>= c1 0))
(assert (>= c2 0))
(assert (>= c3 0))
(assert (>= c4 0))
(assert (>= c5 0))
(assert (>= c6 0))
(assert (>= c7 0))

; each amount is different
(assert (distinct c1 c2 c3 c4 c5 c6 c7))

(declare-fun max () Real)

(assert (and (<= c1 max) (<= c2 max) (<= c3 max) (<= c4 max) (<= c5 max) (<= c6 max) (<= c7 max)))

(assert (or (<= max c1) (<= max c2) (<= max c3) (<= max c4) (<= max c5) (<= max c6) (<= max c7) ))

; make sure there's at least 2 units in the max, per the problem
(assert (<= 2 max))

; final value
(define-fun finalRes () Real (- max 2))

; solve
(check-sat)
(get-value (c1 c2 c3 c4 c5 c6 c7 maxC finalRes))

И результат: 

sat
((c1 2.0)
 (c2 (/ 4.0 3.0))
 (c3 0.0)
 (c4 (/ 1.0 3.0))
 (c5 1.0)
 (c6 (/ 2.0 3.0))
 (c7 (/ 5.0 3.0))
 (max 2.0)
 (finalRes 0.0))
1 голос
/ 17 октября 2019

Конечно. Вот он в SMTLib: 

; declare the cups
(declare-const c1 Real)
(declare-const c2 Real)
(declare-const c3 Real)
(declare-const c4 Real)
(declare-const c5 Real)
(declare-const c6 Real)
(declare-const c7 Real)

; each cup has a non-negative units of water
(assert (>= c1 0))
(assert (>= c2 0))
(assert (>= c3 0))
(assert (>= c4 0))
(assert (>= c5 0))
(assert (>= c6 0))
(assert (>= c7 0))

; each amount is different
(assert (distinct c1 c2 c3 c4 c5 c6 c7))

; find maximum, helper function
(define-fun max ((a Real) (b Real)) Real (ite (> a b) a b))

; find the cup with maximum water in it
(define-fun maxC () Real (max c1 (max c2 (max c3 (max c4 (max c5 (max c6 c7)))))))

; make sure there's at least 2 units in the max, per the problem
(assert (>= maxC 2))

; final value
(define-fun finalRes () Real (- maxC 2))

; solve
(check-sat)
(get-value (c1 c2 c3 c4 c5 c6 c7 maxC finalRes))

z3 говорит: 

sat
((c1 2.0)
 (c2 (/ 11.0 6.0))
 (c3 (/ 19.0 12.0))
 (c4 (/ 7.0 4.0))
 (c5 (/ 3.0 2.0))
 (c6 (/ 23.0 12.0))
 (c7 (/ 5.0 3.0))
 (maxC 2.0)
 (finalRes 0.0))

Итак, похоже, что он помещает 2 единиц в c1, меньше 2 на всехдругие, так что в итоге вы получили окончательное значение 0.

Ваш вопрос довольно расплывчат в отношении того, какие другие ограничения могут быть здесь задействованы, но, надеюсь, это поможет вам начать.

...