Создать настройку Gradle для публикации зависимости с исходным кодом на Jitpack? (Gradle 5.6.2)

Question

Я хочу опубликовать небольшую библиотеку, и мне трудно найти решение для публикации моих источников наряду с зависимостью от jitpack.io.

Файлы классов доступны, но больше ничего.

Это мой файл Gradle:

plugins {

    id 'java-library'
    id 'maven-publish'
}

repositories {

    jcenter()
    mavenCentral()
}
//Problem part
task sourceJar(type: Jar, dependsOn: classes) {
    classifier 'sources'
    from sourceSets.main.allSource
}
task javadocJar(type: Jar, dependsOn: javadoc) {
    classifier = 'javadoc'
    from javadoc.destinationDir
}

artifacts {
    archives sourcesJar
    archives javadocJar
}
//Problem part 
dependencies {
    api 'org.apache.commons:commons-math3:3.6.1'
    implementation 'com.google.guava:guava:27.0.1-jre'
    compile group: 'org.xerial', name: 'sqlite-jdbc', version: '3.28.0'
    compile group: 'com.google.code.gson', name: 'gson', version: '2.8.5'
    compile group: 'org.reflections', name: 'reflections', version: '0.9.11'    

}

Что-то не так с моим файлом Gradle или у кого-нибудь есть предложение, где я могу посмотреть эту проблему?

Answer 1

Решением была конфигурация публикации.

Просто замените задачи и артефакты на:

task sourcesJar(type: Jar) {
    from sourceSets.main.allJava
    archiveClassifier.set("sources")
}
task javadocJar(type: Jar, dependsOn: javadoc) {
     archiveClassifier.set("javadoc")
    from javadoc.destinationDir
}

publishing {
      publications {
          mavenAar(MavenPublication) {
                from components.java
                afterEvaluate {
                    artifact javadocJar
                    artifact sourcesJar
                }
          }
     }
}

И теперь вы можете публиковать / выпускать на Github через Jitpack.io, и он будетприложить ресурсы и документацию.