Ошибка при экспорте Microsoft Access в файл Excel из-за ограничения в 65 000 строк

Question

У меня возникла проблема при экспорте данных Microsoft Access в файл Excel.

Это дает мне сообщение об ошибке:

Вы выбрали больше записей, чем можно скопировать в буфер обмена одновременно. Разделите записи на две или более групп, а затем скопируйте и вставьте одну группу за раз. Максимальное количество записей, которое вы можете вставить за один раз, составляет приблизительно 65 000.

Код, который я использую:

FileCopy "S:\Users\File\Deposit.xls", strs & "\Deposit.xls"

Answer 1

Попробуйте:

Select External data
Got to Export
Hit Excel
You will be given a choice to select the destination for your data
Select where you want to save your exported data
In the Specify Report Options Area- you have the option to select and tick Export Data With Formatting And Layout
You also have the option to open the destination file after the export operation is complete- tick if you want to utilise this option
Hit OK
You may now get the above error at this stage if you have ticked the Export Data With Formatting And Layout Option and are trying to export more than 65,000 data lines
When the data is exported you can then hit Close

Использование VBA:

Sub transSpread()
     DoCmd.TransferSpreadsheet acExport, acSpreadsheetTypeExcel9, _
           "tblSales", "C:\Sales.xls"
     MsgBox "Sales spreadsheet created"
End Sub

Или:

Option Compare Database
Option Explicit

' be sure to select Microsoft Excel Object Library in the References dialog box

Public myExcel As Excel.Application

Sub CopyToExcel()
   Dim conn As ADODB.Connection
   Dim myRecordset As ADODB.Recordset
   Dim wbk As Excel.Workbook
   Dim myWorksheet As Excel.Worksheet
   Dim StartRange As Excel.Range
   Dim strConn As String
   Dim i As Integer
   Dim f As Variant

   On Error GoTo ErrorHandler

   strConn = "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & CurrentProject.Path & "\mydb.mdb"

   Set conn = New ADODB.Connection

   Set myRecordset = New ADODB.Recordset
   With myRecordset
      .Open "Employees", strConn, _
          adOpenKeyset, adLockOptimistic
   End With

   Set myExcel = New Excel.Application
   Set wbk = myExcel.Workbooks.Add
   Set myWorksheet = wbk.ActiveSheet
   myExcel.Visible = True

   i = 1
   With myRecordset
      For Each f In .Fields
         With myWorksheet
            .Cells(1, i).Value = f.Name
            i = i + 1
         End With
      Next
   End With

   Set StartRange = myWorksheet.Cells(2, 1)
   StartRange.CopyFromrecordset myRecordset

   myRecordset.Close
   Set myRecordset = Nothing

   myWorksheet.Columns.AutoFit

   wbk.Close SaveChanges:=True, _
       FileName:="C:\ExcelFile.xls"

   myExcel.Quit
   Set conn = Nothing
   Exit Sub

ErrorHandler:
   MsgBox Err.Description, vbCritical, _
      "Automation Error"
   Set myExcel = Nothing
   Exit Sub
End Sub