Подсчет уникальных значений для уникальных дат в Google Sheets

Question

У меня есть таблица, в которой содержится информация о людях, которые добровольно работали в нескольких организациях в течение одного месяца. Один человек мог добровольно выступить в одной и той же организации в несколько дней, а несколько человек могли добровольно выступить в одну и ту же дату. Я заинтересован в отслеживании для каждой организации уникальных добровольцев (людей, которые добровольно вызвались в любой момент в течение месяца) и уникальных смен (для целей этих данных сменой является один человек, добровольно работающий в уникальную дату).

Как вытащить уникальную метрику смен? Вот пример типа данных, с которыми я имею дело:

Organization | Date       | Volunteer
A            | 10-01-2018 | Jane 
A            | 10-01-2018 | Ben
A            | 10-02-2018 | Jane
B            | 10-01-2018 | Emily
B            | 10-02-2018 | Jack

Вы можете видеть, что Организация A имеет 2 уникальных добровольца и 3 смены, в то время как Организация B имеет 2 уникальных добровольца и 2 смены. Я могу получить уникальное число добровольцев, используя countuniqueifs с организацией в качестве критерия, но чтобы получить число смен, мне нужно, чтобы столбцы «Дата» и «Волонтер» были уникальными, сохраняя при этом организацию каккритерий.

Answer 1

Я заинтересован в отслеживании для каждой организации уникальных добровольцев

=UNIQUE({A2:A, C2:C})

---

=QUERY(UNIQUE({A2:A, C2:C}), 
 "select Col1,count(Col2) 
  where Col1 is not null 
  group by Col1 
  label count(Col2)''", 0)

---

(лица, которые добровольно вызвались в любой момент в течение месяца)

=QUERY(UNIQUE(FILTER({A2:A, C2:C}, MONTH(B2:B)=10)), 
 "select Col1,count(Col2) 
  where Col1 is not null 
  group by Col1 
  label count(Col2)''", 0)

---

и уникальные смены (для целей этих данных сменой является один человек, добровольно работающий в уникальную дату)

=QUERY(UNIQUE(FILTER({A2:A, B2:B&C2:C}, MONTH(B2:B)=10)), 
 "select Col1,count(Col2) 
  where Col1 is not null 
  group by Col1 
  label count(Col2)''", 0)