Перебирать вложенные данные с помощью for / for_each на уровне ресурсов - PullRequest
Новая
       8

Перебирать вложенные данные с помощью for / for_each на уровне ресурсов

0 голосов
/ 11 октября 2019

Я пытаюсь выяснить, как перебирать вложенные переменные из сложного объекта, указанного в следующем файле tfvars, используя Terraform 0.12.10:

example.tfvars 

virtual_network_data = {
  1 = {
    product_instance_id              = 1
    location                         = "somewhere"
    address_space                    = ["192.168.0.0/23"]
    dns_servers                      = []
    custom_tags                      = {"test":"test value"}
    subnets                          = [
      {
        purpose = "mgmt"
        newbits = 4
        item = 0
      },
      {
        purpose = "transit"
        newbits = 4
        item = 1
      }
    ]
  }
}

пример.tf 

variable "virtual_network_data" {} #Data comes from example.tfvars

variable "resource_group_name" {
    default = "my_resource_group"
}

variable "virtual_network_name" {
    default = "my_virtual_network"
}

####

resource "azurerm_subnet" "pool" {
    for_each             = var.virtual_network_data

    name                 = format("%s%s%02d", "subnet_", s.purpose, s.item)
    resource_group_name  = var.resource_group_name
    virtual_network_name = var.virtual_network_name
    address_prefix       = cidrsubnet(each.value["address_space"], s.newbits, s.item)

}

В example.tf Я могу использовать each.value["address_space"], чтобы добраться до переменных верхнего уровня, но не могу понять, как добраться до элементов в subnets (s.purpose, s.item & s.newbits).

Я использовал динамические блоки как часть родительского ресурса (ниже), который работает, но в этом случае мне нужно переместить подсеть в ее собственный ресурс. Проще говоря, как мне заставить первый for_each вести себя как второй for_each в динамическом блоке? 

resource "azurerm_virtual_network" "pool" {
  for_each                  = var.virtual_network_data

  name                      = format("%s%02d", local.resource_name, each.key)
  resource_group_name       = var.resource_group_name
  location                  = each.value["location"]
  address_space             = each.value["address_space"]
  dns_servers               = each.value["dns_servers"]
  tags                      = merge(local.tags, each.value["custom_tags"])

  dynamic "subnet" {
    for_each = [for s in each.value["subnets"]: {
      name   = format("%s%s%02d", "subnet_", s.purpose, s.item)
      prefix = cidrsubnet(element(each.value["address_space"],0), s.newbits, s.item)
    }]

    content {
      name            = subnet.value.name
      address_prefix  = subnet.value.prefix
    }
  }
}

Нахальный бонус, есть ли способ заменить s.item чем-то вроде each.key или count.index?

TIA

1 Ответ

1 голос
/ 12 октября 2019

Техника в этой ситуации заключается в использовании других возможностей языка Terraform для преобразования вашей коллекции в подходящую форму для аргумента for_each: один элемент на экземпляр ресурса.

Для вложенных структур данных вы можетеиспользуйте flatten в сочетании с двумя или более выражениями for для создания плоской структуры данных с одним элементом на вложенный объект: 

locals {
  network_subnets = flatten([
    for network_key, network in var.virtual_network_data : [
      for subnet in network.subnets : {
        network_key       = network_key
        purpose           = subnet.purpose
        parent_cidr_block = network.address_space[0]
        newbits           = subnet.newbits
        item              = subnet.item
      }
    ]
  ])
}

Тогда вы можете использовать local.network_subnets какоснование для повторения: 

resource "azurerm_subnet" "pool" {
    # Each instance must have a unique key, so we'll construct one
    # by combining the network key, the subnet "purpose", and the "item".
    for_each = {
      for ns in local.network_subnets : "${ns.network_key}.${ns.purpose}${ns.item}" => ns
    }

    name                 = format("%s%s%02d", "subnet_", each.value.purpose, each.value.item)
    resource_group_name  = var.resource_group_name
    virtual_network_name = var.virtual_network_name
    address_prefix       = cidrsubnet(each.value.parent_cidr_block, each.value.newbits, each.value.item)
}

В flatten документации есть аналогичный пример, как некоторый дополнительный контекст.

...