Регулярное выражение для сопоставления пользовательского синтаксиса

Question

Я пытаюсь написать регулярное выражение для сопоставления и разбить синтаксис пользовательской переменной в C #. Идея здесь заключается в пользовательском форматировании строковых значений, очень похожих на стиль форматирования строк в .NET String.Format / {0}.

Например, пользователь может определить формат строки для оценки во время выполнения, например:

D:\Path\{LanguageId}\{PersonId}\ 

Значение 'LanguageId' соответствует полю объекта данных, и его текущее значение заменяется.

Ситуация усложняется, когда необходимо передать аргументы в поле форматирования. Например:

{LanguageId:English|Spanish|French}

Это имело бы смысл выполнения некоторой условной логики, если бы значение «LanguageId» было равно одному из аргументов.

Наконец, мне нужно будет поддерживать аргументы карты, например:

{LanguageId:English=>D:\path\english.xml|Spanish=>D:\path\spansih.xml}

Вот перечисление всех возможных значений:

Команда без аргумента : сделать что-то особенное

{@Date}

Один аргумент команды:

{@Date:yyyy-mm-dd}

Без аргументов:

{LanguageId}

Один список аргументов:

{LanguageId:English}

Multi-Argument-list:

{LanguageId:English|Spanish}

Карта одного аргумента:

{LanguageId:English=>D:\path\english.xml}

Мульти Аргумент-карта:

{LanguageId:English=>D:\path\english.xml|Spanish=>D:\path\spansih.xml}

Сводка: синтаксис можно свести к ключу с необязательным списком типов параметров или картой (не обоими). ​​

Ниже приведено Regex, в котором у меня есть несколько проблем, а именно, он не обрабатывает все пробелы правильно, в .NET я не получаю ожидаемые расщепления. Например, в первом примере мне возвращают одно совпадение '{LanguageId} {PersonId}' вместо двух разных совпадений. Также я уверен, что он не обрабатывает путь к файловой системе или строки с разделителями в кавычках. Буду признателен за любую помощь в преодолении горба. Или любые рекомендации.

    private const string RegexMatch = @"
        \{                              # opening curly brace
        [\s]*                           # whitespace before command
        @?                              # command indicator
        (.[^\}\|])+                       # string characters represening command or metadata
        (                               # begin grouping of params
        :                               # required param separater 
        (                               # begin select list param type

        (                               # begin group of list param type
        .+[^\}\|]                       # string of characters for the list item
        (\|.+[^\}\|])*                  # optional multiple list items with separator
        )                               # end select list param type

        |                               # or select map param type

        (                               # begin group of map param type
        .+[^\}\|]=>.+[^\}\|]            # string of characters for map key=>value pair
        (\|.+[^\}\|]=>.+[^\}\|])*       # optional multiple param map items
        )                               # end group map param type

        )                               # end select map param type
        )                               # end grouping of params
        ?                               # allow at most 1 param group
        \s*
        \}                              # closing curly brace
        ";

Answer 1

Вы пытаетесь сделать слишком много с одним регулярным выражением. Я предлагаю вам разбить задачу на этапы, первое из которых - простое совпадение с чем-то, похожим на переменную. Это регулярное выражение может быть так просто, как:

\{\s*([^{}]+?)\s*\}

Это сохраняет всю вашу переменную / командную строку в группе # 1, за исключением фигурных скобок и окружающих пробелов. После этого вы можете разделить на двоеточия, затем трубы, а затем "=>" последовательности в зависимости от ситуации. Не сжимайте всю сложность в одно регулярное выражение монстра; если вам когда-нибудь удастся написать регулярное выражение, вы не сможете поддерживать его, когда ваши требования изменятся позже.

И еще одна вещь: сейчас вы сосредоточены на том, чтобы заставить код работать, когда ввод правильный, но как быть, когда пользователи ошибаются? Не хотели бы вы дать им полезную обратную связь? Регексы сосут в этом; они строго проходят / терпят неудачу. Регулярные выражения могут быть удивительно полезными, но, как и любой другой инструмент, вы должны изучить их ограничения, прежде чем сможете использовать их полную силу.

Answer 2

Возможно, вы захотите взглянуть на реализацию этого как конечного автомата, а не регулярного выражения, в основном для ускоренных циклов. http://en.wikipedia.org/wiki/Finite-state_machine

Редактировать: На самом деле, если быть точным, вы хотите взглянуть на детерминированные конечные автоматы: http://en.wikipedia.org/wiki/Deterministic_finite-state_machine

Answer 3

Это действительно нужно проанализировать.

Например, я хотел разобрать это, используя Regexp::Grammars.

Пожалуйста, извините за длину.

#! /opt/perl/bin/perl
use strict;
use warnings;
use 5.10.1;

use Regexp::Grammars;

my $grammar = qr{
  ^<Path>$

  <objtoken: My::Path>
    <drive=([a-zA-Z])>:\\ <[elements=PathElement]> ** (\\) \\?

  <rule: PathElement>
    (?:
      <MATCH=BlockPathElement>
    |
      <MATCH=SimplePathElement>
    )

  <token: SimplePathElement>
    (?<= \\ ) <MATCH=([^\\]+)>

  <rule: My::BlockPathElement>
    (?<=\\){ \s*
    (?|
      <MATCH=Command>
    |
      <MATCH=Variable>
    )
    \s* }

  <objrule: My::Variable>
    <name=(\w++)> <options=VariableOptionList>?

  <rule: VariableOptionList>
      :
      <[MATCH=VariableOptionItem]> ** ([|])

  <token: VariableOptionItem>
    (?:
      <MATCH=VariableOptionMap>
    |
      <MATCH=( [^{}|]+? )>
    )

  <objrule: My::VariableOptionMap>
    \s*
    <name=(\w++)> => <value=([^{}|]+?)>
    \s*

  <objrule: My::Command>
    @ <name=(\w++)>
    (?:
      : <[arg=CommandArg]> ** ([|])
    )?

  <token: CommandArg>
    <MATCH=([^{}|]+?)> \s*

}x;

Тестирование с:

use YAML;
while( my $line = <> ){
  chomp $line;
  local %/;

  if( $line =~ $grammar ){
    say Dump \%/;
  }else{
    die "Error: $line\n";
  }
}

С примерами данных:

D:\Path\{LanguageId}\{PersonId}
E:\{ LanguageId : English | Spanish | French }
F:\Some Thing\{ LanguageId : English => D:\path\english.xml | Spanish => D:\path\spanish.xml }
C:\{@command}
c:\{@command :arg}
c:\{ @command : arg1 | arg2 }

Результаты:

---
'': 'D:\Path\{LanguageId}\{PersonId}'
Path: !!perl/hash:My::Path
  '': 'D:\Path\{LanguageId}\{PersonId}'
  drive: D
  elements:
    - Path
    - !!perl/hash:My::Variable
      '': LanguageId
      name: LanguageId
    - !!perl/hash:My::Variable
      '': PersonId
      name: PersonId

---
'': 'E:\{ LanguageId : English | Spanish | French }'
Path: !!perl/hash:My::Path
  '': 'E:\{ LanguageId : English | Spanish | French }'
  drive: E
  elements:
    - !!perl/hash:My::Variable
      '': 'LanguageId : English | Spanish | French'
      name: LanguageId
      options:
        - English
        - Spanish
        - French

---
'': 'F:\Some Thing\{ LanguageId : English => D:\path\english.xml | Spanish => D:\path\spanish.xml }'
Path: !!perl/hash:My::Path
  '': 'F:\Some Thing\{ LanguageId : English => D:\path\english.xml | Spanish => D:\path\spanish.xml }'
  drive: F
  elements:
    - Some Thing
    - !!perl/hash:My::Variable
      '': 'LanguageId : English => D:\path\english.xml | Spanish => D:\path\spanish.xml '
      name: LanguageId
      options:
        - !!perl/hash:My::VariableOptionMap
          '': 'English => D:\path\english.xml '
          name: English
          value: D:\path\english.xml
        - !!perl/hash:My::VariableOptionMap
          '': 'Spanish => D:\path\spanish.xml '
          name: Spanish
          value: D:\path\spanish.xml

---
'': 'C:\{@command}'
Path: !!perl/hash:My::Path
  '': 'C:\{@command}'
  drive: C
  elements:
    - !!perl/hash:My::Command
      '': '@command'
      name: command

---
'': 'c:\{@command :arg}'
Path: !!perl/hash:My::Path
  '': 'c:\{@command :arg}'
  drive: c
  elements:
    - !!perl/hash:My::Command
      '': '@command :arg'
      arg:
        - arg
      name: command

---
'': 'c:\{ @command : arg1 | arg2 }'
Path: !!perl/hash:My::Path
  '': 'c:\{ @command : arg1 | arg2 }'
  drive: c
  elements:
    - !!perl/hash:My::Command
      '': '@command : arg1 | arg2 '
      arg:
        - arg1
        - arg2
      name: command

Пример программы:

my %ARGS = qw'
  LanguageId  English
  PersonId    someone
';

while( my $line = <> ){
  chomp $line;
  local %/;

  if( $line =~ $grammar ){
    say $/{Path}->fill( %ARGS );
  }else{
    say 'Error: ', $line;
  }
}

{
  package My::Path;

  sub fill{
    my($self,%args) = @_;

    my $out = $self->{drive}.':';

    for my $element ( @{ $self->{elements} } ){
      if( ref $element ){
        $out .= '\\' . $element->fill(%args);
      }else{
        $out .= "\\$element";
      }
    }

    return $out;
  }
}
{
  package My::Variable;

  sub fill{
    my($self,%args) = @_;

    my $name = $self->{name};

    if( exists $args{$name} ){
      $self->_fill( $args{$name} );
    }else{
      my $lc_name = lc $name;

      my @possible = grep {
        lc $_ eq $lc_name
      } keys %args;

      die qq'Cannot find argument for variable "$name"\n' unless @possible;
      if( @possible > 1 ){
        my $die = qq'Cannot determine which argument matches "$name" closer:\n';
        for my $possible( @possible ){
          $die .= qq'  "$possible"\n';
        }
        die $die;
      }

      $self->_fill( $args{$possible[1]} );
    }
  }
  sub _fill{
    my($self,$opt) = @_;

    # This is just an example.
    unless( exists $self->{options} ){
      return $opt;
    }

    for my $element ( @{$self->{options}} ){
      if( ref $element ){
        return '['.$element->value.']' if lc $element->name eq lc $opt;
      }elsif( lc $element eq lc $opt ){
        return $opt;
      }
    }

    my $name = $self->{name};
    my $die = qq'Invalid argument "$opt" for "$name" :\n';
    for my $valid ( @{$self->{options}} ){
      $die .= qq'  "$valid"\n';
    }
    die $die;
  }
}
{
  package My::VariableOptionMap;

  sub name{
    my($self) = @_;

    return $self->{name};
  }
}
{
  package My::Command;

  sub fill{
    my($self,%args) = @_;

    return '['.$self->{''}.']';
  }
}
{
  package My::VariableOptionMap;

  sub name{
    my($self) = @_;
    return $self->{name};
  }

  sub value{
    my($self) = @_;
    return $self->{value};
  }
}

Вывод с использованием данных примера:

D:\Path\English\someone
E:\English
F:\Some Thing\[D:\path\english.xml]
C:\[@command]
c:\[@command :arg]
c:\[@command : arg1 | arg2 ]