Вычисление суммы значений из родственных элементов с использованием XSLT - PullRequest
Новая
       10

Вычисление суммы значений из родственных элементов с использованием XSLT

1 голос
/ 12 октября 2019

Я работаю над автоматическим преобразованием измерений с использованием XSLT. Преобразование единичных измерений из одной системы (например, в имперскую) в другую (например, метрическую) работает нормальноНо имперские измерения могут принимать форму «5 футов 10 дюймов», и я хотел бы преобразовать это в одно значение метрики.

В моей модели XML я учитываю такие комбинированные измерения, допуская либо одно значение, либо несколькодочерние узлы. Поэтому, когда я обнаружил, что у меня есть дочерние узлы, мне нужно преобразовать каждый из этих дочерних элементов в метрические единицы, а затем сложить значения, чтобы получить один единственный результат метрики.

Я изо всех сил пытаюсь найти лучший способобработать несколько дочерних узлов и сложить результирующие значения. В итеративном языке я бы просто обрабатывал от первого до следующего и обновлял глобальную переменную, но в XSLT я не знаю, существует ли такая вещь, как глобальная переменная, которую можно обновлять при последующих вызовах того же шаблона.

Вот (упрощенное) преобразование - оно обрабатывает только [ft_i] и [in_i] в м. 

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:xs="http://www.w3.org/2001/XMLSchema"
exclude-result-prefixes="xs"
version="2.0">

<xsl:output method="xml" encoding="UTF-8"/>

<xsl:template match="/">
    <xsl:apply-templates/>
</xsl:template>

<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*,node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="measurement">
    <xsl:copy>
        <xsl:choose>
            <xsl:when test="measurement">
                <xsl:apply-templates select="*"/>
            </xsl:when>
            <xsl:otherwise>
                <xsl:call-template name="normalise">
                    <xsl:with-param name="val" as="xs:double" select="number(text())"/>
                    <xsl:with-param name="unitin" select="@ucum"/>
                    <xsl:with-param name="count" as="xs:integer" select="1"/>
                </xsl:call-template>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:copy>
</xsl:template>

<xsl:template name="normalise">
    <xsl:param name="val" as="xs:double"/>
    <xsl:param name="unitin"/>
    <xsl:param name="count" as="xs:integer"/>
    <xsl:choose>
        <xsl:when test="$unitin eq '[ft_i]'">
            <xsl:attribute name="ucum">
                <xsl:value-of select="'m'"/>
            </xsl:attribute>
            <xsl:attribute name="unit">
                <xsl:value-of select="'m'"/>
            </xsl:attribute>
            <xsl:value-of select="$val * 0.3048"/>
        </xsl:when>
        <xsl:when test="$unitin eq '[in_i]'">
            <xsl:attribute name="ucum">
                <xsl:value-of select="'m'"/>
            </xsl:attribute>
            <xsl:attribute name="unit">
                <xsl:value-of select="'m'"/>
            </xsl:attribute>
            <xsl:value-of select="$val * 0.0254"/>
        </xsl:when>
    </xsl:choose>
</xsl:template>

</xsl:stylesheet>

Простой тестовый файл: 

<topic>
    <p>This piece is 
        <measurement>
            <measurement unit="ft" 
                ucum=" [ft_i]">10</measurement>
            <measurement unit="in" 
                ucum="[in_i]">2</measurement>
        </measurement> 
        long
    </p>        
</topic>

Преобразование дает это: 

<topic>
    <p>This piece is 
        <measurement>
            <measurement ucum="m"
                unit="m">3.048</measurement>
            <measurement ucum="m" 
                unit="m">0.0508</measurement>
        </measurement> 
        long
    </p>        
</topic>

Очевидно, я хотел бы видеть это: 

<topic>
    <p>This piece is 
        <measurement ucum="m" 
            unit="m">3.0988</measurement>
        long
    </p>        
</topic>

Я мог бы использовать xsl: for-each на дочерних узлах измерения, но какЯ добавляю отдельные значения к глобальному значению, которое затем может выводиться из основного шаблона?

Ответы [ 3 ]

0 голосов
/ 13 октября 2019

Нет необходимости в многопроходной обработке - XPath 2.0 достаточно силен для решения этой проблемы: 

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

  <xsl:template match="node()|@*">
    <xsl:copy>
      <xsl:apply-templates select="node()|@*"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="measurement[*]">
    <measurement ucum="m" unit="m">
      <xsl:value-of select=
                   "sum(measurement/(. * (if(@ucum eq '[ft_i]') then 0.3048 else 0.0254)))"/>
    </measurement>
  </xsl:template>
</xsl:stylesheet>

Когда это преобразование применяется к предоставленному XMLдокумент: 

<topic>
    <p>This piece is
        <measurement>
            <measurement unit="ft"
                ucum="[ft_i]">10</measurement>
            <measurement unit="in"
                ucum="[in_i]">2</measurement>
        </measurement>
        long
    </p>
</topic>

Требуемый, правильный результат получается: 

<topic>
    <p>This piece is
        <measurement ucum="m" unit="m">3.0988</measurement>
        long
    </p>
</topic>

II. Более общее решение

Можно создать более общее решение, в котором преобразование выделено в отдельный XSLT <xsl:function>. Обратите внимание, что это решение будет работать даже в тех случаях, когда логика преобразования настолько сложна, что не может быть выражена в одном выражении XPath , как это было возможно в приведенном выше решении. Если преобразование не является простым умножением, то вообще невозможно представить его в виде таблицы и использовать xsl:key: 

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:f="my:f" exclude-result-prefixes="f">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

  <xsl:template match="node()|@*">
    <xsl:copy>
      <xsl:apply-templates select="node()|@*"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="measurement[*]">
    <measurement ucum="m" unit="m">
      <xsl:value-of select="sum(measurement/f:convert(@ucum, .))"/>
    </measurement>
  </xsl:template>

  <xsl:function name="f:convert">
    <xsl:param name="pFromUnit"/>
    <xsl:param name="pValue"/>

    <xsl:value-of select=
    "$pValue * (if($pFromUnit eq '[ft_i]') then 0.3048 else 0.0254)"/>
  </xsl:function>
</xsl:stylesheet>

Когда это преобразование применяется к тому же XMLдокумент (выше), тот же правильный, желаемый результат выдается снова : 

<topic>
    <p>This piece is
        <measurement ucum="m" unit="m">3.0988</measurement>
        long
    </p>
</topic>
0 голосов
/ 13 октября 2019

Предполагая, что вы можете иметь более 2-х единиц, было бы удобно сохранить их в переменной и получить соответствующий коэффициент преобразования, используя ключ :

XSLT 2.0

<xsl:stylesheet version="2.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<xsl:key name="unit" match="unit" use="@name" />

<xsl:variable name="units">
    <unit name="ft" factor=".3048"/>
    <unit name="in" factor=".0254"/>
    <!-- add more units here ... -->
</xsl:variable>

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="measurement[measurement]">
    <measurement ucum="m" unit="m">
        <xsl:value-of select="sum(measurement/(. * key('unit', @unit, $units)/@factor))"/>    
    </measurement>
</xsl:template>

</xsl:stylesheet>

Демо : https://xsltfiddle.liberty -development.net / 6rewNxT

0 голосов
/ 12 октября 2019

Если предположить, что некоторые значения и атрибуты являются постоянными, самый простой подход будет использовать сложное выражение XPath-2.0. Затем вы можете уменьшить ваш шаблон measurement до: 

<xsl:template match="measurement">
    <measurement ucum="m" unit="m">
        <xsl:copy-of select="sum(for $x in measurement return if (normalize-space($x/@ucum)= '[ft_i]') then xs:double(normalize-space($x))*0.3048 else xs:double(normalize-space($x))*0.0254)" />
    </measurement>
</xsl:template>

Предполагается, что атрибуты остаются неизменными и что существует только две единицы. Но вы могли бы легко его расширить.

При создании шаблонов на основе вашего подхода также возможно следующее решение: 

<xsl:template match="measurement">
    <xsl:copy>
        <xsl:variable name="summary">
            <xsl:for-each select="measurement">
                <val>
                    <xsl:call-template name="normalise">
                        <xsl:with-param name="val" as="xs:double" select="number(.)"/>
                        <xsl:with-param name="unitin" select="@ucum"/>
                        <xsl:with-param name="count" as="xs:integer" select="1"/>
                    </xsl:call-template>
                </val>
            </xsl:for-each>
        </xsl:variable>
        <xsl:copy-of select="$summary/val[1]/@*" />
        <xsl:copy-of select="sum($summary/val)" />
    </xsl:copy>
</xsl:template>

<xsl:template name="normalise">
    <xsl:param name="val" as="xs:double"/>
    <xsl:param name="unitin"/>
    <xsl:param name="count" as="xs:integer"/>
    <xsl:choose>
        <xsl:when test="normalize-space($unitin) = '[ft_i]'">
            <xsl:attribute name="ucum">
                <xsl:value-of select="'m'"/>
            </xsl:attribute>
            <xsl:attribute name="unit">
                <xsl:value-of select="'m'"/>
            </xsl:attribute>
            <xsl:value-of select="$val * 0.3048"/>
        </xsl:when>
        <xsl:when test="normalize-space($unitin) = '[in_i]'">
            <xsl:attribute name="ucum">
                <xsl:value-of select="'m'"/>
            </xsl:attribute>
            <xsl:attribute name="unit">
                <xsl:value-of select="'m'"/>
            </xsl:attribute>
            <xsl:value-of select="$val * 0.0254"/>
        </xsl:when>
    </xsl:choose>
</xsl:template>

Это более гибкий и использует двухэтапный подходс переменной. Результат тот же. Я полагаю, если вы объедините оба, вы найдете хороший способ удовлетворить ваши потребности.

...