Как взять фрагмент списка (подсписок) в схеме?

Question

Учитывая список, как мне выбрать новый список, содержащий фрагмент исходного списка (с учетом смещения и количества элементов)?

EDIT:

Хорошие предложения до сих пор. Разве что-то не указано в одном из SRFI? Кажется, это очень фундаментальная вещь, поэтому я удивлен, что мне нужно реализовать ее в пользовательской среде.

Answer 1

Как ни странно, slice не предоставляется с SRFI-1 , но вы можете сократить его, используя take и drop SRFI-1 *:

(define (slice l offset n)
  (take (drop l offset) n))

Я думал, что одно из расширений, которые я использовал со Scheme, например библиотека PLT Scheme или Swindle, будет иметь эту встроенную функцию, но, похоже, это не так. Это даже не определено в новых библиотеках R6RS.

Answer 2

Следующий код сделает то, что вы хотите:

(define get-n-items
    (lambda (lst num)
        (if (> num 0)
            (cons (car lst) (get-n-items (cdr lst) (- num 1)))
            '()))) ;'

(define slice
    (lambda (lst start count)
        (if (> start 1)
            (slice (cdr lst) (- start 1) count)
            (get-n-items lst count))))

Пример:

> (define l '(2 3 4 5 6 7 8 9)) ;'
()
> l
(2 3 4 5 6 7 8 9)
> (slice l 2 4)
(3 4 5 6)
> 

Answer 3

Вы можете попробовать эту функцию:

subseq начало последовательности и необязательный конец

Параметр start является вашим смещением. Параметр end можно легко превратить в число элементов для захвата, просто добавив start + количество элементов.

Небольшой бонус в том, что subseq работает на всех последовательностях, включая не только списки, но также строки и векторы.

Редактировать: Кажется, что не во всех реализациях lisp есть subseq, хотя он отлично справится с этой задачей, если он у вас есть.

Answer 4

Вот моя реализация slice, которая использует правильный хвостовой вызов

(define (slice a b xs (ys null))
  (cond ((> a 0) (slice (- a 1) b (cdr xs) ys))
        ((> b 0) (slice a (- b 1) (cdr xs) (cons (car xs) ys)))
        (else (reverse ys))))

(slice 0 3 '(A B C D E F G)) ;=> '(A B C)
(slice 2 4 '(A B C D E F G)) ;=> '(C D E F)

Answer 5

(define (sublist list start number)
  (cond ((> start 0) (sublist (cdr list) (- start 1) number))
        ((> number 0) (cons (car list)
                      (sublist (cdr list) 0 (- number 1))))
        (else '())))

Answer 6

Попробуйте что-то вроде этого:

    (define (slice l offset length)
      (if (null? l)
        l
        (if (> offset 0)
            (slice (cdr l) (- offset 1) length)
            (if (> length 0)
                (cons (car l) (slice (cdr l) 0 (- length 1)))
                '()))))