Плавное движение в обработке

Question

Я пытался создать плавное движение при обработке, но сейчас он не работает, и я не уверен, почему он не работает. Я новичок в кодировании, поэтому не делайте это слишком сложным для меня при объяснении :). Сейчас персонаж движется очень скованно, и я не могу нажимать несколько кнопок одновременно, было бы неплохо, если бы кто-то мог мне помочь. Заранее спасибо.

class Player1 {
    int x = width/2;
    int y;
    float speedX = 5;
    float speedY = 5;
    int size;

    boolean up, down, left, right;

    Player1(int newX, int newY, int newSize) {
        x = newX;
        y = newY;
        size = newSize;
    }

    void run() {
        display();
        movePlayer1();
    }

    void display() {
        ellipse(x, y, size, size);
    }

    void movePlayer1() {
        if (keyPressed) {
            if (key == 'a' || key == 'A') {
                left = true;
            }
            if (key == 'd' || key == 'D') {
                right = true;
            }
            if (key == 'w' || key == 'W') {
                up = true;
            }
            if (key == 's' || key == 'S') {
                down = true;
            }

            if (key == 'a' || key == 'A') {
                x -= speedX;
            }
            if (key == 'd' || key == 'D') {
                x += speedX;
            }
            if (key == 'w' || key == 'W') {
                y -= speedY;
            }
            if (key == 's' || key == 'S') {
                y += speedY;
            }
        }
    }

    void keyReleased() {
        if (key == 'a' || key == 'A') {
            left = false;
        }
        if (key == 'd' || key == 'D') {
            right = false;
        }
        if (key == 'w' || key == 'W') {
            up = false;
        }
        if (key == 's' || key == 'S') {
            down = false;
        }
      }
}

Это основная кодовая страница

Stars stars[] = new Stars[100];
Player1 player1;
Player2 player2;


void setup() {
    size(600, 800);
    player1 = new Player1(width/2, 100, 30);
    player2 = new Player2(width/2, 700, 30);

    for (int i = 0; i < stars.length; i++) {
        stars[i] = new Stars((int)random(width), (int)random(height));
    }
}

void draw() {
    background(0); 
    stroke(255);
    strokeWeight(3);
    line(0, height/2, width, height/2);


    //draw stars
    for (int i = 0; i < stars.length; i++) {
        stars[i].run();
    }

    // draw players
    player1.run();
    player2.run();

}

Answer 1

Прежде всего, я рекомендую изменить класс Player1 соответственно Player2. Не используйте другой класс, для объектов, которые ведут себя одинаково. Обратите внимание, единственное отличие состоит в том, что игроки перемещаются разными клавишами, это не должно обрабатываться разными объектами.
Создать отдельный класс Player. Класс использует новые методы pressed и released, которые изменяют текущее направление движения (dx, dy) в зависимости от входных параметров left, right, up и * 1012. *. Например:

class Player {  
    int x, y;
    int dx = 0, dy = 0;
    float speedX = 5;
    float speedY = 5;
    int size;

    Player(int newX, int newY, int newSize) {
        x = newX;
        y = newY;
        size = newSize;
    }

    void run() {
        display();
        movePlayer();
    }

    void movePlayer() {
        x += dx * speedX;
        y += dy * speedY;
    }

    void display() {
        ellipse(x, y, size, size);
    }

    void pressed(boolean left, boolean right, boolean up, boolean down) {
        if (left)  dx = -1;
        if (right) dx =  1;
        if (up)    dy = -1;
        if (down)  dy =  1;
    }

    void released(boolean left, boolean right, boolean up, boolean down) { 
        if (left)  dx = 0;
        if (right) dx = 0;
        if (up)    dy = 0;
        if (down)  dy = 0;
    }
} 

Используйте электронные обратные вызовы клавиатуры keyPressed() и keyReleased(), чтобы изменить движение игроков. Параметры left, right, up и down устанавливаются в зависимости от нажатых или отпущенных клавиш. Например:

Player player1;
Player player2;

void setup() {
    // [...]
}

void draw() {
    // [...]
}

void keyPressed() {
    player1.pressed((key == 'a' || key == 'A'), (key == 'd' || key == 'D'),
                    (key == 'w' || key == 'W'), (key == 's' || key == 'S'));

    player2.pressed(keyCode == LEFT, keyCode == RIGHT, keyCode == UP, keyCode == DOWN);
}

void keyReleased() {
    player1.released((key == 'a' || key == 'A'), (key == 'd' || key == 'D'),
                     (key == 'w' || key == 'W'), (key == 's' || key == 'S'));

    player2.released(keyCode == LEFT, keyCode == RIGHT, keyCode == UP, keyCode == DOWN);
}

Это позволяет обрабатывать состояние нескольких клавиш одновременно.