Ищите кодирование SAS для вычисления баллов для всей когорты на основе баллов, рассчитанных для подгруппы - PullRequest
Новая
       10

Ищите кодирование SAS для вычисления баллов для всей когорты на основе баллов, рассчитанных для подгруппы

0 голосов
/ 01 ноября 2019

Я ищу кодирование SAS для вычисления баллов для всей когорты на основе баллов, рассчитанных для подгруппы.

. Я могу самостоятельно создавать баллы для всей совокупности как мой набор данных, но не имею опыта использованияподогнанные значения набора данных подгруппы для вычисления баллов для всего населения

Я работаю с кодированием SAS

NA

1 Ответ

0 голосов
/ 03 ноября 2019

Добро пожаловать в stackoverflow! Если я понимаю ваш вопрос, это будет делать то, что вы хотите.

Я собрал некоторые данные из sas support : 

  Data Neuralgia;
      input Treatment $ Sex $ Age Duration Pain $ @@;
      datalines;
   P  F  68   1  No   B  M  74  16  No  P  F  67  30  No
   P  M  66  26  Yes  B  F  67  28  No  B  F  77  16  No
   A  F  71  12  No   B  F  72  50  No  B  F  76   9  Yes
   A  M  71  17  Yes  A  F  63  27  No  A  F  69  18  Yes
   B  F  66  12  No   A  M  62  42  No  P  F  64   1  Yes
   A  F  64  17  No   P  M  74   4  No  A  F  72  25  No
   P  M  70   1  Yes  B  M  66  19  No  B  M  59  29  No
   A  F  64  30  No   A  M  70  28  No  A  M  69   1  No
   B  F  78   1  No   P  M  83   1  Yes B  F  69  42  No
   B  M  75  30  Yes  P  M  77  29  Yes P  F  79  20  Yes
   A  M  70  12  No   A  F  69  12  No  B  F  65  14  No
   B  M  70   1  No   B  M  67  23  No  A  M  76  25  Yes
   P  M  78  12  Yes  B  M  77   1  Yes B  F  69  24  No
   P  M  66   4  Yes  P  F  65  29  No  P  M  60  26  Yes
   A  M  78  15  Yes  B  M  75  21  Yes A  F  67  11  No
   P  F  72  27  No   P  F  70  13  Yes A  M  75   6  Yes
   B  F  65   7  No   P  F  68  27  Yes P  M  68  11  Yes
   P  M  67  17  Yes  B  M  70  22  No  A  M  65  15  No
   P  F  67   1  Yes  A  M  67  10  No  P  F  72  11  Yes
   A  F  74   1  No   B  M  80  21  Yes A  F  69   3  No
   ;
run;

Затем поместил их вниз, чтобы построить модель, используятолько мужчины: 

data males;
    set Neuralgia;
    where sex = "M";
run;

Затем я построил модель и сохранил детали модели в рабочей библиотеке в файле с именем theMaleModel. 

proc logistic data=males outmodel=work.theMaleModel;
    class Treatment;
    model Pain = Treatment Age Duration ;
run;

Затем я применяю модель мужчинык полному набору данных и сохраните результаты в наборе данных в рабочей библиотеке, называемой ScoreEverybody: 

proc logistic inmodel=work.theMaleModel;
   score data=Neuralgia out=scoreEverybody;
run;

Подобные примеры можно увидеть, если вы посмотрите здесь . Если это отвечает на ваш вопрос, пожалуйста, нажмите на флажок рядом с этим ответом.

...