Как включить пустой набор узлов в мюнхенскую группировку XSLT?

Question

Я хочу преобразовать мой XML в группы строк и столбцов через <RowBreak> и <ColumnBreak>. Теперь я могу успешно преобразовать его с помощью мюнхенской группировки, но как мне включить пустые узлы? В приведенном ниже примере есть два <ColumnBreak /> с пустой строкой между ними, поэтому ожидаемый результат:

XML:

<?xml version="1.0" encoding="utf-8" ?>
<Tree>
  <Item>
    <Label>Item 1</Label>
  </Item>
  <Item>
    <Label>Item 2</Label>
  </Item>
  <ColumnBreak /> 
  <ColumnBreak />
  <Item>
    <Label>Item 3</Label>
  </Item>
  <Item>
    <Label>Item 4</Label>
  </Item>
  <Item>
    <Label>Item 5</Label>
  </Item>
  <RowBreak />
  <Item>
    <Label>Item 6</Label>
  </Item>
  <Item>
    <Label>Item 7</Label>
  </Item>
  <ColumnBreak />
  <Item>
    <Label>Item 8</Label>
  </Item>
  <RowBreak />
  <Item>
    <Label>Item 9</Label>
  </Item>
  <Item>
    <Label>Item 10</Label>
  </Item>
</Tree>

XSLT:

<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:exsl="http://exslt.org/common"
extension-element-prefixes="exsl">
  <xsl:output method="xml" version="1.0" encoding="utf-8" indent="yes"/>

  <xsl:key name="cell-by-row" match="cell" use="@row" />
  <xsl:key name="cell-by-col" match="cell" use="concat(@row, '|', @col)" />

  <xsl:template match="/Tree">
    <xsl:variable name="cells">
      <xsl:apply-templates select="*[1]" mode="sibling">
        <xsl:with-param name="row" select="1"/>
        <xsl:with-param name="col" select="1"/>
      </xsl:apply-templates>
    </xsl:variable>
    <table border = "1">
      <xsl:for-each select="exsl:node-set($cells)/cell[count(. | key('cell-by-row', @row)[1]) = 1]">
        <tr>
          <xsl:for-each select="key('cell-by-row', @row)[count(. | key('cell-by-col', concat(@row, '|', @col))[1]) = 1]">
            <td>
              <xsl:for-each select="key('cell-by-col', concat(@row, '|', @col))">
                <xsl:value-of select="."/>
                <br/>
              </xsl:for-each>
            </td>
          </xsl:for-each>
        </tr>
      </xsl:for-each>
    </table>
  </xsl:template>

  <xsl:template match="*" mode="sibling">
    <xsl:param name="row"/>
    <xsl:param name="col"/>
    <cell row="{$row}" col="{$col}">
      <xsl:value-of select="Label"/>
    </cell>
    <xsl:apply-templates select="following-sibling::*[1]" mode="sibling">
      <xsl:with-param name="row" select="$row"/>
      <xsl:with-param name="col" select="$col"/>
    </xsl:apply-templates>
  </xsl:template>

  <xsl:template match="ColumnBreak" mode="sibling">
    <xsl:param name="row"/>
    <xsl:param name="col"/>
    <xsl:apply-templates select="following-sibling::*[1]" mode="sibling">
      <xsl:with-param name="row" select="$row"/>
      <xsl:with-param name="col" select="$col + 1"/>
    </xsl:apply-templates>
  </xsl:template>

  <xsl:template match="RowBreak" mode="sibling">
    <xsl:param name="row"/>
    <xsl:param name="col"/>
    <xsl:apply-templates select="following-sibling::*[1]" mode="sibling">
      <xsl:with-param name="row" select="$row + 1"/>
      <xsl:with-param name="col" select="1"/>
    </xsl:apply-templates>
  </xsl:template>
</xsl:stylesheet>

Answer 1

Единственное исправление, которое вы можете сделать, не внося больших изменений в свой XSLT, - это изменить шаблон ColumnBreak, чтобы проверить, является ли предыдущий брат другим, чем Item. В этом случае вы можете добавить «пустую» ячейку

<xsl:template match="ColumnBreak" mode="sibling">
  <xsl:param name="row"/>
  <xsl:param name="col"/>
  <xsl:if test="not(preceding-sibling::*[1][self::Item])">
    <cell row="{$row}" col="{$col}" empty="true" />
  </xsl:if>
  <xsl:apply-templates select="following-sibling::*[1]" mode="sibling">
    <xsl:with-param name="row" select="$row"/>
    <xsl:with-param name="col" select="$col + 1"/>
  </xsl:apply-templates>
</xsl:template>

Затем в своем основном шаблоне вы можете проверить наличие пустых ячеек

<xsl:for-each select="key('cell-by-col', concat(@row, '|', @col))">
  <xsl:if test="not(@empty)">
    <xsl:value-of select="."/>
    <br/>
  </xsl:if>
</xsl:for-each>

На самом деле, вы даже можете опуститьотметьте здесь @empty, если вы рады, что пустая ячейка имеет тег <br />.

См. http://xsltfiddle.liberty -development.net / jz1PuP1