Выберите элемент из выпадающего на странице Internet Explorer с VBScript

Question

Я пытаюсь открыть URL и выбрать значение из раскрывающегося списка, а затем отправить форму, но я не могу выбрать значение из раскрывающегося списка.

Это мой текущий код:

Dim vb
Dim ie

Set vb = CreateObject("WScript.Shell")
Set ie = CreateObject("InternetExplorer.Application")

'start IE
ie.Visible = True
ie.Navigate "https://www.nseindia.com/live_market/dynaContent/live_watch/equities_stock_watch.htm"

'Loop until page load
Do While ie.Busy
    WScript.Sleep 200
Loop
WScript.Sleep 200

'Activate ie windows
vb.AppActivate ("NSE - National Stock Exchange of India Ltd. - Internet Explorer")
WScript.Sleep 200

'Now i want to select from dropdown, How can i select option from dropdown list.

'Submit the form
ie.Document.All.Item("dataform").Submit

Set vb = Nothing
Set ie = Nothing

Answer 1

Вы также можете попробовать использовать следующий код:

        For Each objOption In IE.Document.getElementById("bankNiftySelect").getElementsByTagName("option")
            With objOption
                If .Value = "foSec" Then
                    .Selected = True
                Else
                    .Selected = False
                End If
            End With
        Next

Answer 2

Обычно вы перебираете все опции и выбираете тот, который вам нужен:

For Each objOption In ie.Document.getElementById("bankNiftySelect").Options

    With objOption
        If .Value = "foSec" Then
            .Selected = True
        Else
            .Selected = False
        End If
    End With

Next