(Широкий) String - хранение в TFileStream, Delphi 7. Какой самый быстрый способ?

Question

Я использую Delphi7 (не-Unicode VCL), мне нужно хранить множество WideStrings внутри TFileStream. Я не могу использовать TStringStream, так как (широкие) строки смешиваются с двоичными данными, формат проецируется для ускорения загрузки и записи данных ... Однако я считаю, что текущий способ загрузки / записи строк может быть узкое место моего кода ...

В настоящее время я пишу длину строки, а затем пишу ее как char by char ... при загрузке сначала загружаю длину, затем загружаю char по char ...

Итак, какой самый быстрый способ сохранить и загрузить WideString в TFileStream?

Заранее спасибо

Answer 1

В широких строках нет ничего особенного, чтобы читать и писать их как можно быстрее, вам нужно читать и писать как можно больше за один раз:

procedure TForm1.Button1Click(Sender: TObject);
var
  Str: TStream;
  W, W2: WideString;
  L: integer;
begin
  W := 'foo bar baz';

  Str := TFileStream.Create('test.bin', fmCreate);
  try
    // write WideString
    L := Length(W);
    Str.WriteBuffer(L, SizeOf(integer));
    if L > 0 then
      Str.WriteBuffer(W[1], L * SizeOf(WideChar));

    Str.Seek(0, soFromBeginning);
    // read back WideString
    Str.ReadBuffer(L, SizeOf(integer));
    if L > 0 then begin
      SetLength(W2, L);
      Str.ReadBuffer(W2[1], L * SizeOf(WideChar));
    end else
      W2 := '';
    Assert(W = W2);
  finally
    Str.Free;
  end;
end;

Answer 2

Вместо того чтобы читать и писать по одному символу за раз, читайте и пишите их все сразу:

procedure WriteWideString(const ws: WideString; stream: TStream);
var
  nChars: LongInt;
begin
  nChars := Length(ws);
  stream.WriteBuffer(nChars, SizeOf(nChars);
  if nChars > 0 then
    stream.WriteBuffer(ws[1], nChars * SizeOf(ws[1]));
end;

function ReadWideString(stream: TStream): WideString;
var
  nChars: LongInt;
begin
  stream.ReadBuffer(nChars, SizeOf(nChars));
  SetLength(Result, nChars);
  if nChars > 0 then
    stream.ReadBuffer(Result[1], nChars * SizeOf(Result[1]));
end;

Технически, поскольку WideString - это Windows BSTR, она может содержать нечетное количество байтов. Функция Length считывает количество байтов и делит на два, поэтому вполне возможно (хотя и маловероятно), что приведенный выше код обрежет последний байт. Вы можете использовать этот код вместо:

procedure WriteWideString(const ws: WideString; stream: TStream);
var
  nBytes: LongInt;
begin
  nBytes := SysStringByteLen(Pointer(ws));
  stream.WriteBuffer(nBytes, SizeOf(nBytes));
  if nBytes > 0 then
    stream.WriteBuffer(Pointer(ws)^, nBytes);
end;

function ReadWideString(stream: TStream): WideString;
var
  nBytes: LongInt;
  buffer: PAnsiChar;
begin
  stream.ReadBuffer(nBytes, SizeOf(nBytes));
  if nBytes > 0 then begin
    GetMem(buffer, nBytes);
    try
      stream.ReadBuffer(buffer^, nBytes);
      Result := SysAllocStringByteLen(buffer, nBytes)
    finally
      FreeMem(buffer);
    end;
  end else
    Result := '';
end;

Вдохновленный ответом Мги , заменил мои Read и Write звонки на ReadBuffer и WriteBuffer. Последние вызовут исключения, если они не смогут прочитать или записать запрошенное количество байтов.

Answer 3

WideStrings содержат «строку» WideChar, которая использует 2 байта каждая. Если вы хотите сохранить строки UTF-16 (которые WideStrings используют для внутреннего использования) в файле и можете использовать этот файл в других программах, таких как блокнот, вам нужно сначала написать знак порядка байтов : #$FEFF.

Если вы знаете это, письмо может выглядеть так:

Stream1.Write(WideString1[1],Length(WideString)*2); //2=SizeOf(WideChar)

чтение может выглядеть так:

Stream1.Read(WideChar1,2);//assert returned 2 and WideChar1=#$FEFF
SetLength(WideString1,(Stream1.Size div 2)-1);
Stream1.Read(WideString1[1],(Stream1.Size div 2)-1);

Answer 4

Вы также можете использовать TFastFileStream для чтения данных или строк, я вставил единицу в http://pastebin.com/m6ecdc8c2 и пример ниже:

program Project36;

{$APPTYPE CONSOLE}

uses
  SysUtils, Classes,
  FastStream in 'FastStream.pas';

const
  WideNull: WideChar = #0;

procedure WriteWideStringToStream(Stream: TFileStream; var Data: WideString);
var
  len: Word;
begin
  len := Length(Data);
  // Write WideString length
  Stream.Write(len, SizeOf(len));
  if (len > 0) then
  begin
    // Write WideString
    Stream.Write(Data[1], len * SizeOf(WideChar));
  end;
  // Write null termination
  Stream.Write(WideNull, SizeOf(WideNull));
end;

procedure CreateTestFile;
var
  Stream: TFileStream;
  MyString: WideString;
begin
  Stream := TFileStream.Create('test.bin', fmCreate);
  try
    MyString := 'Hello World!';
    WriteWideStringToStream(Stream, MyString);

    MyString := 'Speed is Delphi!';
    WriteWideStringToStream(Stream, MyString);
  finally
    Stream.Free;
  end;
end;

function ReadWideStringFromStream(Stream: TFastFileStream): WideString;
var
  len: Word;
begin
  // Read length of WideString
  Stream.Read(len, SizeOf(len));
  // Read WideString
  Result := PWideChar(Cardinal(Stream.Memory) + Stream.Position);
  // Update position and skip null termination
  Stream.Position := Stream.Position + (len * SizeOf(WideChar)) + SizeOf(WideNull);
end;

procedure ReadTestFile;
var
  Stream: TFastFileStream;

  my_wide_string: WideString;
begin
  Stream := TFastFileStream.Create('test.bin');
  try
    Stream.Position := 0;
    // Read WideString
    my_wide_string := ReadWideStringFromStream(Stream);
    WriteLn(my_wide_string);
    // Read another WideString
    my_wide_string := ReadWideStringFromStream(Stream);
    WriteLn(my_wide_string);
  finally
    Stream.Free;
  end;
end;

begin
  CreateTestFile;
  ReadTestFile;
  ReadLn;
end.