Печатать элементы списка, но обрабатывать последний элемент по-разному

Question

Я написал предикат, который печатает каждый элемент в списке, кроме последнего. Последний элемент должен обрабатываться по-разному;вместо этого должно быть напечатано LAST!. Это то, что у меня есть.

write_data([]).
write_data([X]) :-
    !, write('LAST!'), nl.
write_data([X | Rest]) :-
    write(x), nl,
    write_data(Rest).

Есть ли лучший способ? Есть ли способ сделать это без разреза?

Answer 1

Общее определение для предиката last/2, предоставляющего доступ к последнему элементу списка:

last([Head| Tail], Last) :-
    last(Tail, Head, Last).

last([], Last, Last).
last([Head| Tail], _, Last) :-
    last(Tail, Head, Last).

При вызове с первым аргументом, связанным с закрытым списком, вспомогательный предикат, last/3, избегает ложных точек выбора, предполагая, что система Prolog реализует обычную индексацию первого аргумента. Можете ли вы изменить этот предикат, чтобы делать то, что вы хотите?

Answer 2

Вы можете избежать сокращения, выполнив объединение со списком, который содержит как минимум два элемента, например:

write_data([]).
write_data([_]) :-
    write('LAST!'),
    nl.
write_data([X|Rest]) :-
    <b>Rest = [_|_],</b>
    write(X), nl,
    write_data(Rest).

Кроме того, мы можем избежать двойной распаковки с предикатом-помощником:

write_data([]).
write_data([H|T]) :-
    write_data(T, H).

write_data([], _) :-
    write('LAST!'), nl.
write_data([H|T], X) :-
    write(X), nl,
    write_data(T, H).

Answer 3

Общее правило для удаления среза заключается в том, чтобы отметить, что было true в предложении, которое содержит разрез, а затем убедиться, что * false в другом пункте (ах).

Таким образом:

write_data([]).

write_data([X]) :-
    /*!,*/write('LAST!'), nl.

write_data([X | Rest]) :-
    dif(Rest,[]) , /**/
    write(x), nl,
    write_data(Rest).