Как перенаправить вывод DBMS_OUTPUT.PUT_LINE в файл?

Question

Мне нужно отладить в pl / sql для определения времени процедур, которые я хочу использовать:

SELECT systimestamp FROM dual INTO time_db;
DBMS_OUTPUT.PUT_LINE('time before procedure ' || time_db);

но я не понимаю, куда направляются выходные данные и как я могу перенаправить их в файл журнала, который будет содержать все данные, которые я хочу собрать?

Answer 1

DBMS_OUTPUT не лучший инструмент для отладки, так как большинство сред не используют его изначально. Однако, если вы хотите захватить вывод DBMS_OUTPUT, просто воспользуйтесь процедурой DBMS_OUTPUT.get_line.

Вот небольшой пример:

SQL> create directory tmp as '/tmp/';

Directory created

SQL> CREATE OR REPLACE PROCEDURE write_log AS
  2     l_line VARCHAR2(255);
  3     l_done NUMBER;
  4     l_file utl_file.file_type;
  5  BEGIN
  6     l_file := utl_file.fopen('TMP', 'foo.log', 'A');
  7     LOOP
  8        EXIT WHEN l_done = 1;
  9        dbms_output.get_line(l_line, l_done);
 10        utl_file.put_line(l_file, l_line);
 11     END LOOP;
 12     utl_file.fflush(l_file);
 13     utl_file.fclose(l_file);
 14  END write_log;
 15  /

Procedure created

SQL> BEGIN
  2     dbms_output.enable(100000);
  3     -- write something to DBMS_OUTPUT
  4     dbms_output.put_line('this is a test');
  5     -- write the content of the buffer to a file
  6     write_log;
  7  END;
  8  /

PL/SQL procedure successfully completed

SQL> host cat /tmp/foo.log

this is a test

Answer 2

Как альтернатива записи в файл, как насчет записи в таблицу? Вместо вызова DBMS_OUTPUT.PUT_LINE вы можете вызвать свою собственную процедуру DEBUG.OUTPUT что-то вроде:

procedure output (p_text varchar2) is
   pragma autonomous_transaction;
begin
   if g_debugging then
      insert into debug_messages (username, datetime, text)
      values (user, sysdate, p_text);
      commit;
   end if;
end;

Использование автономной транзакции позволяет вам сохранить отладочные сообщения, созданные из транзакций, которые откатываются (например, после возникновения исключения), как это было бы, если бы вы использовали файл.

Логическая переменная g_debugging - это переменная пакета, которая может быть установлена ​​по умолчанию в false и иметь значение true, когда требуется отладочный вывод.

Конечно, вам нужно управлять этой таблицей, чтобы она не росла вечно! Одним из способов может быть задание, которое выполняется еженедельно / еженедельно и удаляет все «старые» отладочные сообщения.

Answer 3

использование включить выход сервера;

например:

set serveroutput on;

DECLARE
x NUMBER;
BEGIN
x := 72600;
dbms_output.put_line('The variable X = '); dbms_output.put_line(x);
END;

Answer 4

Если вы просто тестируете свой PL / SQL в SQL Plus, вы можете направить его в файл, подобный следующему:

spool output.txt
set serveroutput on

begin
  SELECT systimestamp FROM dual INTO time_db;
  DBMS_OUTPUT.PUT_LINE('time before procedure ' || time_db);
end;
/

spool off

IDE, такие как Toad и SQL Developer, могут захватывать вывод другими способами, но я не знаю, как.

Answer 5

В дополнение к ответу Тони, если вы хотите узнать, где ваша программа PL / SQL тратит свое время, стоит также проверить эту часть документации Oracle PL / SQL.

Answer 6

Обратите внимание, что все эти выходные данные генерируются на стороне сервера.

Используя DBMS_OUTPUT, текст генерируется на сервере во время выполнения вашего запроса и сохраняется в буфере. Затем он перенаправляется в ваше клиентское приложение, когда сервер завершает поиск данных запроса. То есть вы получите эту информацию только после завершения запроса.

При использовании UTL_FILE вся зарегистрированная информация будет храниться в файле на сервере. Когда выполнение завершится, вам придется перейти к этому файлу, чтобы получить информацию.

Надеюсь, это поможет.

Answer 7

Использование UTL_FILE вместо DBMS_OUTPUT перенаправит вывод в файл:

http://oreilly.com/catalog/oraclebip/chapter/ch06.html

Answer 8

Возможно записать файл непосредственно на сервер БД, на котором размещена ваша база данных, и он будет меняться вместе с выполнением вашей программы PL / SQL.

Используется каталог Oracle TMP_DIR; Вы должны объявить это и создать следующую процедуру:

CREATE OR REPLACE PROCEDURE write_log(p_log varchar2)
  -- file mode; thisrequires
--- CREATE OR REPLACE DIRECTORY TMP_DIR as '/directory/where/oracle/can/write/on/DB_server/';
AS
  l_file utl_file.file_type;
BEGIN
  l_file := utl_file.fopen('TMP_DIR', 'my_output.log', 'A');
  utl_file.put_line(l_file, p_log);
  utl_file.fflush(l_file);
  utl_file.fclose(l_file);
END write_log;
/

Вот как это использовать:

1) Запустите это из своего клиента SQL * PLUS:

BEGIN
  write_log('this is a test');
  for i in 1..100 loop
    DBMS_LOCK.sleep(1);
    write_log('iter=' || i);
  end loop;
  write_log('test complete');
END;
/

2) на сервере базы данных откройте оболочку и

    tail -f -n500 /directory/where/oracle/can/write/on/DB_server/my_output.log

Answer 9

Старая тема, но есть и другая альтернатива.

Начиная с 9i, ​​вы можете использовать конвейерную табличную функцию.

Сначала создайте тип в виде таблицы varchar:

CREATE TYPE t_string_max IS TABLE OF VARCHAR2(32767);

Во-вторых, оберните ваш код в объявление конвейерной функции:

CREATE FUNCTION fn_foo (bar VARCHAR2) -- your params
  RETURN t_string_max PIPELINED IS 
  -- your vars
BEGIN
  -- your code
END;
/

Заменить все DBMS_OUTPUT.PUT_LINE на PIPE ROW.

Наконец, назовите это так:

SELECT * FROM TABLE(fn_foo('param'));

Надеюсь, это поможет.

Answer 10

Попробуйте:

SELECT systimestamp INTO time_db FROM dual ;

DBMS_OUTPUT.PUT_LINE('time before procedure ' || time_db);