SQL Server: создать инкрементный счетчик для записей в том же году?

Question

У меня есть таблица со следующими столбцами:

EmployeeID
EventDate (mm/dd/yyyy)
Event

Мне нужно создать новый столбец, который будет подсчитывать каждое событие по году и вставлять значение в формате ## - гггг. Например, я хочу создать файл, такой как Counter:

EmployeeID      EventDate   Event   Counter
------------------------------------------
  001           01/05/2018    A     01-2018
  002           12/12/2018    A     01-2018
  001           03/01/2019    A     01-2019
  001           04/05/2019    A     02-2019
  002           05/05/2019    A     01-2018

Мне не нужно считать по событию или типу события. Мне просто нужно включить счетчик для каждого события в году и увеличить для каждого события дату, когда это произошло. Таким образом, событие в январе 2019 года будет иметь меньшее число, чем событие в июне 2019 года.

Answer 1

Если это был SQL-сервер:

SELECT
   ...,
   CONCAT(
     FORMAT(
       ROW_NUMBER() OVER(PARTITION BY employeeid, YEAR(eventdate) ORDER BY eventdate ASC), 
       'D2'
     ), 
     '-', 
     YEAR(eventdate)
   ) as counter
FROM ...

ROW_NUMBER () увеличит счетчик с 1, который перезапускает каждого сотрудника / год. Мы форматируем это так, чтобы иметь начальный 0, а затем добавляем дефис и год

Если вы хотите, чтобы все события в одном месяце имели одинаковое число, рассмотрите DENSE_RANK() OVER(PARTITION BY employeeid, YEAR(eventdate) ORDER BY MONTH(eventdate)) вместо номера строки.

Answer 2

В Access вам понадобится пользовательская функция, такая как my RowNumber , которая позволяет группировать:

' Builds consecutive row numbers in a select, append, or create query
' with the option of a initial automatic reset.
' Optionally, a grouping key can be passed to reset the row count
' for every group key.
'
' 2018-08-23. Gustav Brock, Cactus Data ApS, CPH.
'
Public Function RowNumber( _
    ByVal Key As String, _
    Optional ByVal GroupKey As String, _
    Optional ByVal Reset As Boolean) _
    As Long

    ' Uncommon character string to assemble GroupKey and Key as a compound key.
    Const KeySeparator      As String = "¤§¤"
    ' Expected error codes to accept.
    Const CannotAddKey      As Long = 457
    Const CannotRemoveKey   As Long = 5

    Static Keys             As New Collection
    Static GroupKeys        As New Collection
    Dim Count               As Long
    Dim CompoundKey         As String

    On Error GoTo Err_RowNumber

    If Reset = True Then
        ' Erase the collection of keys and group key counts.
        Set Keys = Nothing
        Set GroupKeys = Nothing
    Else
        ' Create a compound key to uniquely identify GroupKey and its Key.
        ' Note: If GroupKey is not used, only one element will be added.
        CompoundKey = GroupKey & KeySeparator & Key
        Count = Keys(CompoundKey)

        If Count = 0 Then
            ' This record has not been enumerated.
            '
            ' Will either fail if the group key is new, leaving Count as zero,
            ' or retrieve the count of already enumerated records with this group key.
            Count = GroupKeys(GroupKey) + 1
            If Count > 0 Then
                ' The group key has been recorded.
                ' Remove it to allow it to be recreated holding the new count.
                GroupKeys.Remove (GroupKey)
            Else
                ' This record is the first having this group key.
                ' Thus, the count is 1.
                Count = 1
            End If
            ' (Re)create the group key item with the value of the count of keys.
            GroupKeys.Add Count, GroupKey
        End If
        ' Add the key and its enumeration.
        ' This will be:
        '   Using no group key: Relative to the full recordset.
        '   Using a group key:  Relative to the group key.
        ' Will fail if the key already has been created.
        Keys.Add Count, CompoundKey
    End If

    ' Return the key value as this is the row counter.
    RowNumber = Count

Exit_RowNumber:
    Exit Function

Err_RowNumber:
    Select Case Err
        Case CannotAddKey
            ' Key is present, thus cannot be added again.
            Resume Next
        Case CannotRemoveKey
            ' GroupKey is not present, thus cannot be removed.
            Resume Next
        Case Else
            ' Some other error. Ignore.
            Resume Exit_RowNumber
    End Select
End Function

Тогда ваш запрос может быть:

SELECT 
    EmployeeID, 
    EventDate, 
    Event, 
    RowNumber(CStr([EventDate]),[EmployeeID] & "-" & CStr(Year([EventDate]))) AS RowCount, 
    Format([RowCount],"00-") & CStr(Year([EventDate])) AS EventCount
FROM 
    Events
WHERE 
    RowNumber(CStr([EventDate]),[EmployeeID] & "-" & CStr(Year([EventDate])))<>RowNumber("","",True)
ORDER BY 
    EventDate;

и результат будет:

Полный код можно найти на GitHub : VBA.RowNumbers

Answer 3

С некоторыми отличиями от ответа @Caius Jard, что почти правильно.

SELECT 
    EmployeeID,
    EventDate,
    [Event],
    FORMAT(ROW_NUMBER() OVER(PARTITION BY DATEPART(YEAR, EventDate), EmployeeID, [Event] ORDER BY EventDate ASC) , 'D2') 
    + '-' 
    + FORMAT(DATEPART(YEAR, EventDate), 'D4') AS Counter
FROM YOUR_TABLE