Получить имена столбцов в своем собственном столбце для визуализации круговой диаграммы

Question

Я пишу запрос в Кусто, чтобы разобрать данные сердцебиения с датчика. Вот что я написал:

datatable(timestamp:datetime, healthycount:int, unhealthycount:int, origin:string)
[
    datetime(1910-06-11), 10, 1, 'origin',
    datetime(1910-05-11), 9, 2, 'origin'
]
| summarize latest = arg_max(timestamp, *) by origin
| project healthy = healthycount,
    unhealthy = unhealthycount

Это выводит данные примерно так:

+--------------+----------------+
|   healthy    |   unhealthy    |
+--------------+----------------+
|           10 |              1 |
+--------------+----------------+

Однако я хочу представить эти данные в виде круговой диаграммы, но для этого янужны данные в следующем формате:

+----------------+-------+
|      key       | value |
+----------------+-------+
| healthy        |    10 |
| unhealthy      |     1 |
+----------------+-------+

Возможно ли это сделать? Какую терминологию я ищу?

Answer 1

Вот один из способов:

datatable(timestamp:datetime, healthycount:int, unhealthycount:int, origin:string)
[
    datetime(1910-06-11), 10, 1, 'origin',
    datetime(1910-05-11), 9, 2, 'origin'
]
| summarize arg_max(timestamp, *) by origin
| extend Pack = pack("healthycount", healthycount, "unhealthycount", unhealthycount)
| mv-expand kind=array Pack 
| project key = tostring(Pack[0]), value = toint(Pack[1])