Формула Excel для расчета значений на основе других ячеек

Question

У меня есть следующая таблица:

Я использую следующую формулу в column F, чтобы получить сумму значений в column E: =SUMIFS(E:E,C:C,LEFT(TRIM(RIGHT([@[Object Name]],LEN([@[Object Name]])-FIND("=",[@[Object Name]]))),4),A:A,INT([@[Result Time]])) но это не похоже на работу.

Оценивая формулу, я получаю следующий результат:

Может кто-нибудь, пожалуйста, взять взятие за

Answer 1

Вы ищете имя объекта "T054", когда все они выглядят как "CELL = T054CID" ... поэтому результаты не возвращаются.

Что именно вы пытаетесьделать?

Есть ли причина, по которой вы не можете просто сделать:

=SUMIFS([3G_Traffic_CS],[Object Name],[@[Object Name]],[Result Time],[@[Result Time]])

Вы также заметите, что я ссылаюсь только наячейки столбца в таблице, а не весь столбец. Это более эффективно и предотвращает подсчет любых дополнительных значений, которые появляются под таблицей (маловероятно, но не невозможно).

ALTERNATIVE (Использование столбца помощника)

Добавитьвспомогательный столбец, который содержит усеченное значение Имени объекта и сравнивается с ним:

=SUMIFS([3G_Traffic_CS],[Trimmed Object Name],[@[Trimmed Object Name]],[Result Time],[@[Result Time]])

ДРУГОЙ АЛЬТЕРНАТИВНЫЙ (Использование FIND и SUMPRODUCT)

Если вы хотите включить любое имя объекта, которое СОДЕРЖИТ ваше усеченное значение, вы можете сделать это, используя функцию FIND с SUMPRODUCT:

=SUMPRODUCT(
    ([Result Time]=[@[Result Time]])*
    (ISNUMBER(
        FIND(LEFT(TRIM(RIGHT([@[Object Name]],LEN([@[Object Name]])-FIND("=",[@[Object Name]]))),4),
            [Object Name]
        )
    ))*
    [3G_Traffic_CS]
)

ЕЩЕ ДРУГОЙ АЛЬТЕРНАТИВЫ (Использование подстановочного знака согласно комментарию @ Jvdv)

Сноваэто предполагает, что вы хотите включить все имена объектов, которые CONTAIN идентифицируют ваш обрезанный идентификатор сайта. Просто добавьте «*» в начало и конец вашего обрезанного имени объекта.

=SUMIFS([3G_Traffic_CS],
    [Object Name],
    CONCAT("*",
        LEFT(TRIM(RIGHT([@[Object Name]],LEN([@[Object Name]])-FIND("=",[@[Object Name]]))),4),
        "*"
    ),
    [Result Time],
    INT([@[Result Time]])
)