Объединение по нескольким столбцам в Azure (язык запросов Kusto)

Question

У меня есть данные о кликах в журналах монитора Azure в следующем формате:

Category   StepName     Count_    Median_Duration(secs)
   A         step1       1200        00:00
   A         step2       1000        24:00
   A         step3        800        19:00
   B         step1       4000        00:00
   B         step2       3800        37:00

Мне нужно повернуть таблицу, чтобы получить следующее:

Category Step1_Count Step1_Duration Step2_Count Step2_Duration Step3_Count ...
   A       1200          00:00         1000        24:00          800      ...
   B       4000          00:00         3800        37:00           0       ...

В настоящее время я могу толькоагрегировать по одному столбцу, используя оценку pivot (StepName, sum (Count_)) или оценку pivot (StepName, sum (Median_Duration)). Можно ли получить вышеуказанный формат без использования объединений?

Примечание. Форматы, аналогичные формату выходной таблицы, хороши, просто необходимо указать общее количество и продолжительность.

Answer 1

вы можете попробовать что-то вроде следующего:

datatable(Category:string, StepName:string, Count_:long, Median_Duration:timespan)
[
   "A", "step1", 1200, time(00:00:00),
   "A", "step2", 1000, time(00:00:24),
   "A", "step3",  800, time(00:00:19),
   "B", "step1", 4000, time(00:00:00),
   "B", "step2", 3800, time(00:00:37),
]
| summarize StepCount = sum(Count_), Duration = avg(Median_Duration) by Category, StepName
| project Category, p = pack(strcat(StepName, "_Count"), StepCount, strcat(StepName, "_Duration"), Duration)
| summarize b = make_bag(p) by Category
| evaluate bag_unpack(b)

или, если вы в порядке с другой схемой вывода:

datatable(Category:string, StepName:string, Count_:long, Median_Duration:timespan)
[
   "A", "step1", 1200, time(00:00:00),
   "A", "step2", 1000, time(00:00:24),
   "A", "step3",  800, time(00:00:19),
   "B", "step1", 4000, time(00:00:00),
   "B", "step2", 3800, time(00:00:37),
]
| summarize StepCount = sum(Count_), Duration = avg(Median_Duration) by Category, StepName