запомнить или использовать значение переменной из предыдущей итерации - программирование с сохранением состояния в xsl

Question

Я должен выяснить, смотрю ли я на href id впервые или нет.

У меня есть следующие ссылки:

<a href="some_fn_1">link1</a>
<a href="some_fn_2">link2</a>
<a href="some_fn_1">link1</a>

Давайте просто скажем Значение атрибута href является идентификатором

. Я должен преобразовать эти ссылки в следующие, используя xsl:

<fn id="some_fn_1">
    link1
</fn>
<fn href="some_fn_2">
    link2
</fn>
<xref href="some_fn_1"/>

Итак, что мне нужно сделать, так это перебрать все узлы 'a' с помощью Перейдите по документу и вспомните, встречал ли я когда-нибудь ссылку на конкретный идентификатор. Создайте узел для первого href, и если другой href указывает на тот же Id, я должен сгенерировать xref. Так что я должен вспомнить ранее посещенные href id. Я пробовал следующее:

<xsl:param name="processed-footnotes"/>
<xsl:template match="//a[contains(@href, '_fn_')]">
    <xsl:param name="processed-footnotes" select="concat($processed-footnotes, concat(concat('~', substring-after(@href,'/')), '~'))"/>
    <xsl:variable name="fn-href">
        <xsl:value-of select="@href"/>
    </xsl:variable>
    <xsl:variable name="fn-id">
        <xsl:value-of select="substring-after($fn-href,'/')"/>
    </xsl:variable>
    <xsl:call-template name="process-footnotes">
        <xsl:with-param name="fn-href" select="$fn-href"/>
        <xsl:with-param name="fn-id" select="$fn-id"/>
    </xsl:call-template>
</xsl:template>

Я намеревался использовать $ Обработанные сноски в качестве глобального параметра, который я могу обновлять для каждого href, который я нахожу, но переназначение или обновление значения для параметра или переменной не возможно в xsl.

Я не знаю, как добиться этого с помощью xsl сейчас. Пожалуйста, помогите.

Answer 1

Рассмотрим следующий пример:

XML

<input>
    <a href="some_fn_1">link1</a>
    <a href="some_fn_2">link2</a>
    <a href="some_fn_1">link1</a>
</input>

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>

<xsl:key name="a" match="a" use="@href" />

<xsl:template match="/input">
    <output>
        <xsl:for-each select="a">
            <xsl:choose>
                <xsl:when test="count(. | key('a', @href)[1]) = 1">
                <!-- this is the first occurrence of this href value -->
                    <fn id="{@href}">
                        <xsl:value-of select="."/>
                    </fn>
                </xsl:when>
                <xsl:otherwise>
                    <xref href="{@href}"/>
                </xsl:otherwise>
            </xsl:choose>
        </xsl:for-each>
    </output>
</xsl:template>

</xsl:stylesheet>

Результат

<?xml version="1.0" encoding="UTF-8"?>
<output>
  <fn id="some_fn_1">link1</fn>
  <fn id="some_fn_2">link2</fn>
  <xref href="some_fn_1"/>
</output>

---

Чтобы лучше понять, как это работает, прочитайте: http://www.jenitennison.com/xslt/grouping/muenchian.html

Answer 2

Решение, основанное на ключах, уже было предложено и хорошо, возможно, формулировка в XSLT 2/3, не требующая использования сравнения на основе count или generate-id для проверки идентичности узла, полезна для понимания подхода, кроме того Я предпочитаю делегировать преобразование шаблонам, поэтому здесь есть несколько иной способ:

<xsl:stylesheet
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    version="3.0">

  <xsl:mode on-no-match="shallow-copy"/>

  <xsl:key name="group" match="a[contains(@href, '_fn_')]" use="@href"/>

  <xsl:template match="a[contains(@href, '_fn_')][. is key('group', @href)[1]]">
      <fn id="{@href}">
          <xsl:apply-templates/>
      </fn>
  </xsl:template>

  <xsl:template match="a[contains(@href, '_fn_')][not(. is key('group', @href)[1])]">
      <xref href="{@href}"/>
  </xsl:template>

</xsl:stylesheet>

https://xsltfiddle.liberty-development.net/6rexjhG/1

Понижение до XSLT 1 приведет к

<xsl:stylesheet
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    version="1.0">

  <xsl:key name="group" match="a[contains(@href, '_fn_')]" use="@href"/>

  <xsl:template match="@* | node()">
    <xsl:copy>
      <xsl:apply-templates select="@* | node()"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="a[contains(@href, '_fn_')][generate-id() = generate-id(key('group', @href)[1])]">
      <fn id="{@href}">
          <xsl:apply-templates/>
      </fn>
  </xsl:template>

  <xsl:template match="a[contains(@href, '_fn_')][generate-id() != generate-id(key('group', @href)[1])]">
      <xref href="{@href}"/>
  </xsl:template>

</xsl:stylesheet>

https://xsltfiddle.liberty-development.net/6rexjhG

В XSLT 3 использование аккумулятора также является альтернативой, которая могла бы работать даже с потоковой передачей:

<xsl:stylesheet
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    xmlns:map="http://www.w3.org/2005/xpath-functions/map"
    exclude-result-prefixes="#all"
    version="3.0">

  <xsl:mode on-no-match="shallow-copy" streamable="yes" use-accumulators="link-id-counts"/>

  <xsl:accumulator name="link-id-counts" as="map(xs:string, xs:integer)" initial-value="map{}" streamable="yes">
      <xsl:accumulator-rule
         match="a[contains(@href, '_fn_')]"
         select="map:put($value, string(@href), ($value(@href), 0)[1] + 1)"/>
  </xsl:accumulator>

  <xsl:template match="a[contains(@href, '_fn_')][accumulator-before('link-id-counts')(@href) = 1]">
      <fn id="{@href}">
          <xsl:apply-templates/>
      </fn>
  </xsl:template>

  <xsl:template match="a[contains(@href, '_fn_')][accumulator-before('link-id-counts')(@href) > 1]">
      <xref href="{@href}"/>
  </xsl:template>

</xsl:stylesheet>

https://xsltfiddle.liberty-development.net/6rexjhG/2