Использование предиката forall () в minizin c в качестве оператора присваивания без «ограничений» - PullRequest
Новая
       18

Использование предиката forall () в minizin c в качестве оператора присваивания без «ограничений»

2 голосов
/ 08 апреля 2020

У меня есть программа Minizin c для генерации оптимального графика зарядки / разрядки для батареи, подключенной к сети, с учетом набора цен по временному интервалу.

Моя программа работает (в некотором роде; тема к некоторым оговоркам), но мой вопрос о двух «ограничивающих» утверждениях, которые на самом деле являются просто операторами присваивания: 

constraint forall(t in 2..T)(MW_SETPOINT[t-1] - SALE[t] = MW_SETPOINT[t]);
constraint forall(t in 1..T)(PROFIT[t] = SALE[t] * PRICE[t]);

Это просто означает, что Энергия SALES является дельтой в MW_SETPOINT от t-1 до 1, а PROFIT равно SALE * PRICE для каждого интервала. Поэтому мне кажется нелогичным объявлять их «ограничениями». Но я не смог сформулировать их как операторы присваивания без появления синтаксических ошибок.

Вопрос:

  • Существует ли более идиоматический c способ объявления таких операторов присваивания для массива, который является функцией других параметров / переменных? Или выполняет назначения для массивов в constraint s рекомендуемый / идиоматический c способ сделать это в Minizin c?

Полная программа для контекста: 

% PARAMS
int: MW_CAPACITY = 10;
array[int] of float: PRICE; 

% DERIVED PARAMS
int: STARTING_MW = MW_CAPACITY div 2;  % integer division
int: T = length(PRICE);

% DECISION VARIABLE - MW SETPOINT EACH INTERVAL
array[1..T] of var 0..MW_CAPACITY: MW_SETPOINT;

% DERIVED/INTERMEDIATE VARIABLES
array[1..T] of var -1*MW_CAPACITY..MW_CAPACITY: SALE;  
array[1..T] of var float: PROFIT;
var float: NET_PROFIT = sum(PROFIT);

% CONSTRAINTS
%% If start at 5MW, and sell 5 first interval, setpoint for first interval is 0 
constraint MW_SETPOINT[1] = STARTING_MW - SALE[1];  

%% End where you started; opt schedule from arbitrage means no net MW over time
constraint MW_SETPOINT[T] = STARTING_MW;            

%% these are really justassignment statements for SALE & PROFIT
constraint forall(t in 2..T)(MW_SETPOINT[t-1] - SALE[t] = MW_SETPOINT[t]);
constraint forall(t in 1..T)(PROFIT[t] = SALE[t] * PRICE[t]);

% OBJECTIVE: MAXIMIZE REVENUE
solve maximize NET_PROFIT;

output["DAILY_PROFIT: " ++ show(NET_PROFIT) ++ 
      "\nMW SETPOINTS: " ++ show(MW_SETPOINT) ++ 
      "\nMW SALES: " ++ show(SALE) ++
      "\n$/MW PRICES: " ++ show(PRICE)++
      "\nPROFITS: " ++ show(PROFIT)
      ];

Может быть запущен с 

minizinc opt_sched_hindsight.mzn --solver org.minizinc.mip.coin-bc -D "PRICE = [29.835, 29.310470000000002, 28.575059999999997, 28.02416, 28.800690000000003, 32.41052, 34.38542, 29.512390000000003, 25.66587, 25.0499, 26.555529999999997, 28.149440000000002, 30.216509999999996, 32.32415, 31.406609999999997, 36.77642, 41.94735, 51.235209999999995, 50.68137, 64.54481, 48.235170000000004, 40.27663, 34.93675, 31.10404];"```

1 Ответ

5 голосов
/ 08 апреля 2020

Вы можете играть с Массивами : (цитата из документов)

Массивы имеют следующий синтаксис: 

<array-comp> ::= "[" <expr> "|" <comp-tail> "]"

Например (с буквальными эквивалентами справа): 

[2*i | i in 1..5]       % [2, 4, 6, 8, 10]

Массивное понимание имеет более гибкие требования к типу и экземпляру, чем наборное понимание (см. Установить понимание ).

Разрешены массивы для набора переменных с конечным типом, результатом является массив необязательного типа, длина которого равна количеству элементов верхней границы набора переменных. Например: 

var set of 1..5: x;
array[int] of var opt int: y = [ i * i | i in x ];

Длина массива будет равна 5.

Допускается понимание массива, где выражением where является var bool. Опять же, результирующий массив имеет необязательный тип и имеет длину, равную длине, заданной выражениями генератора Например: 

var int x;
array[int] of var opt int: y = [ i | i in 1..10 where i != x ];

Длина массива будет 10.

Индексы вычисленного простого понимания массива неявно 1..n, где n - длина оцениваемое понимание.

Пример: 

int: MW_CAPACITY = 10;
int: STARTING_MW = MW_CAPACITY div 2;

array [int] of float: PRICE = [1.0, 2.0, 3.0, 4.0];
int: T = length(PRICE);

array [1..T] of var -1*MW_CAPACITY..MW_CAPACITY: SALE;

array [1..T] of var 0..MW_CAPACITY: MW_SETPOINT = let {
        int: min_i = min(index_set(PRICE));
    } in  
        [STARTING_MW - sum([SALE[j] | j in min_i..i])
         | i in index_set(PRICE)];

array [1..T] of var float: PROFIT =
        [SALE[i] * PRICE[i]
         | i in index_set(PRICE)];

solve satisfy;

Вывод: 

~$ minizinc test.mzn 
SALE = array1d(1..4, [-10, -5, 0, 0]);
----------

Обратите внимание, что index_set(PRICE) - это не что иное, как 1..T и min(index_set(PRICE)) - это не что иное, как 1, поэтому можно написать вышеприведенные массивы также как 

array [1..T] of var 0..MW_CAPACITY: MW_SETPOINT =
        [STARTING_MW - sum([SALE[j] | j in 1..i])
         | i in 1..T];

array [1..T] of var float: PROFIT =
        [SALE[i] * PRICE[i]
         | i in 1..T];
...