Пытаюсь сделать калькулятор с бизоном и флексом, но он только распечатывает 0 - PullRequest
Новая
       22

Пытаюсь сделать калькулятор с бизоном и флексом, но он только распечатывает 0

0 голосов
/ 09 апреля 2020

Я следовал учебному пособию из книги «Flex and Bison» Джона Левина, где я пытаюсь создать калькулятор в C с помощью Flex и Bison. Однако, когда я пытаюсь использовать мою реализацию, она выводит только 0 независимо от того, какие вычисления я ввожу. Я пытался найти проблему часами, но я не вижу, что случилось. Вот мой flex, bison и makefile в соответствующем порядке:

cal c .l 

%{
 #include "calc.tab.h"
%}
%%
"+"     { return ADD; }
"-"     { return SUB; }
"*"     { return MUL; }
"/"     { return DIV; }
"|"     { return ABS; }
[0-9]+  { yylval = atoi(yytext); return NUMBER; }
\n      { return EOL; }
[ \t]   { }
"//".   { }
"("     { return OP; }
")"     { return CP; }
.       { printf("Unkown character: %s\n", yytext); }
%%

cal c .y 

%{
#include <stdio.h>
%}

%token NUMBER
%token ADD SUB MUL DIV ABS
%token EOL
%token OP CP

%%

calclist:
  | calclist exp EOL { printf("= %d\n", $1); }
  ;

exp: factor        { $$ = $1; }
  | exp ADD factor { $$ = $1 + $3; }
  | exp SUB factor { $$ = $1 - $3; }
  ;

factor: term        { $$ = $1; }
  | factor MUL term { $$ = $1 * $3; }
  | factor DIV term { $$ = $1 / $3; }
  ;

term: NUMBER  { $$ = $1; }
  | ABS term  { $$ = $2 >= 0? $2 : - $2; }
  | OP exp CP { $$ = $2; }
  ;
%%
main(int argc, char **argv)
{
  yyparse();
}

yyerror(char *s)
{
  fprintf(stderr, "error: %s\n", s);
}

makefile 

calc: calc.l calc.y
      bison -d calc.y
      flex calc.l
      cc -o $@ calc.tab.c lex.yy.c -lfl

1 Ответ

3 голосов
/ 09 апреля 2020

В этом произведении: 

calclist exp EOL { printf("= %d\n", $1); }

$1 относится к calclist, но ничто не дало этому нетерминальному значению.

Что имеет значение, и что вы на самом деле хотите напечатать, это exp, который является вторым символом в правой части и, следовательно, соответствует $2.

...