Индикатор выполнения в окне Applescript - PullRequest
Новая
       55

Индикатор выполнения в окне Applescript

0 голосов
/ 14 апреля 2020

Я хочу загружать различные приложения с помощью скрипта bash в macOS.

Поскольку есть несколько более крупных загрузок (например, Office 365), я бы хотел включить индикатор выполнения в обычное окно macOS.

Скрипт загрузки и установки приложений выглядит следующим образом 

cd ~/Downloads/ && { curl -O https://dl.google.com/chrome/mac/stable/GGRO/googlechrome.dmg ; cd -; }
sudo hdiutil attach ~/Downloads/googlechrome.dmg
sudo cp -r /Volumes/Google\ Chrome/Google\ Chrome.app /Applications/
diskutil unmount Google\ Chrome

Но это не показывает никакого прогресса для пользователя (скрипт будет работать в фоновом режиме).

Я нашел Следующий пример и немного его отредактировал по своему вкусу 

chromedl() {
    osascript <<AppleScript
    set progress description to "Loading"
set progress additional description to "Please wait"
set progress total steps to 3
repeat with i from 1 to 4
   set theSourceCode to do shell script "curl -L -m 30 seconds [url=https://dl.google.com/chrome/mac/stable/GGRO/googlechrome.dmg]https://dl.google.com/chrome/mac/stable/GGRO/googlechrome.dmg]"
   set progress completed steps to i
end repeat
display dialog "Progress bar is complete."
AppleScript

Но это создает ошибку выполнения curl.

Пожалуйста, помогите мне с работающим скриптом Curl Download + Progress Bar

1 Ответ

0 голосов
/ 20 апреля 2020

Основное c окно счетчика хода выполнения достаточно просто создать с помощью AppleScriptObjective C. Скопируйте следующее в Редактор сценариев и запустите его на переднем плане (команда-control-R, или используйте команду меню Сценарий → Выполнить на переднем плане, которая появляется, когда вы удерживаете нажатой клавишу управления). 

use framework "AppKit"
use AppleScript version "2.4" -- Yosemite 10.10 or later required
use scripting additions

-- convenience properties to make ASOC more readable
property ca : current application
property NSPanel : class "NSPanel"
property NSView : class "NSView"
property NSProgressIndicator : class "NSProgressIndicator"
property NSTextField : class "NSTextField"

property HUD_mask : 8192
property nonactivating_mask : 128

global progress_panel, progress_indicator, label_field

make_progress_panel()
progress_indicator's startAnimation:me
progress_panel's orderFront:me

-- just hang it out there for 5 seconds as proof of concept
delay 5

progress_panel's |close|()

on make_progress_panel()
    -- make floating panel
    set content_rect to ca's NSMakeRect(200, 800, 140, 80)
    set progress_panel to NSPanel's alloc's initWithContentRect:content_rect styleMask:(HUD_mask + nonactivating_mask) backing:(ca's NSBackingStoreBuffered) defer:true
    set progress_panel's floatingPanel to true

    -- make progress indicator
    set progress_rect to ca's NSMakeRect(0, 0, 40, 40)
    set progress_indicator to NSProgressIndicator's alloc's initWithFrame:progress_rect
    set progress_indicator's indeterminate to true
    set progress_indicator's |style| to 1
    set progress_indicator's translatesAutoresizingMaskIntoConstraints to false

    --make text field
    set label_field to NSTextField's labelWithString:"Downloading"
    set label_field's translatesAutoresizingMaskIntoConstraints to false

    -- make container view, and add subviews
    set content_view to NSView's alloc's initWithFrame:content_rect
    content_view's addSubview:label_field
    content_view's addSubview:progress_indicator
    progress_indicator's sizeToFit()

    set progress_panel's contentView to content_view

    -- view constraints, for alignment
    set pi_y_centering to progress_indicator's centerYAnchor's constraintEqualToAnchor:(content_view's centerYAnchor)
    set lf_y_centering to label_field's centerYAnchor's constraintEqualToAnchor:(content_view's centerYAnchor)
    pi_y_centering's setActive:true
    lf_y_centering's setActive:true

    set lf_left_margin to content_view's leadingAnchor's constraintEqualToAnchor:(label_field's leadingAnchor) |constant|:-10
    lf_left_margin's setActive:true

    set pi_left_margin to label_field's trailingAnchor's constraintEqualToAnchor:(progress_indicator's leadingAnchor) |constant|:-10
    pi_left_margin's setActive:true

    set pi_right_margin to progress_indicator's trailingAnchor's constraintGreaterThanOrEqualToAnchor:(content_view's trailingAnchor) |constant|:10
    pi_left_margin's setActive:true
end make_progress_panel

Я думаю, что самый простой способ заставить это работать с curl - полностью отделить процесс curl и восстановить его pid, вот так (код в конце отсоединяет процесс и отправляет вывод в забвение, а затем возвращает pid) : 

set curl_pid to do shell script "curl -L [url=...] &> /dev/null & echo $!"

Получив pid, вы можете настроить al oop (или обработчик простоя, если создаете приложение) и периодически проверять, все ли процесс активен: 

try
    set b to do shell script "pgrep curl | grep " & curl_pid
on error
    progress_indicator's stopAnimation:me
    progress_panel's |close|()
end try

Если вам нужен определенный индикатор прогресса, управлять им достаточно просто, но вы должны найти способ измерить прогресс. Эта ссылка предполагает, что вы можете сначала получить заголовки для файла и извлечь размер файла; Вы можете сравнить это с фактическим размером файла на диске в процессе загрузки и вставить соотношение в индикатор выполнения.

...