Как посчитать следующих братьев и сестер :: * [1] [self :: disp-quote]

Question

Как считать following-sibling::*[1][self::disp-quote] позиция ПРИМЕР S / B ПРИМЕР 1

Входной файл

    <?xml version="1.0" encoding="UTF-8"?>
<sec>
    <title>Title</title>
    <p>vlvvnlfjkvv</p>
    <disp-quote><p content-type="example"><bold>EXAMPLE</bold> aaaaaaa</p></disp-quote>
    <disp-quote><p content-type="example"><bold>EXAMPLE</bold> aaaaaaa</p></disp-quote>
    <disp-quote><p content-type="example"><bold>EXAMPLE</bold> aaaaaaa</p></disp-quote>
    <p>aaaaaa</p>
    <p>aaaaaa</p>
    <disp-quote><p content-type="example"><bold>EXAMPLE</bold> aaaaaaa</p></disp-quote>
    <p>vvvkvuvhv</p>
</sec>

Ожидаемый результат

    <?xml version="1.0" encoding="UTF-8"?>
<sec>
    <title>Title</title>
    <p>vlvvnlfjkvv</p>
    <disp-quote><p content-type="example"><bold>EXAMPLE 1</bold> aaaaaaa</p></disp-quote>
    <disp-quote><p content-type="example"><bold>EXAMPLE 2</bold> aaaaaaa</p></disp-quote>
    <disp-quote><p content-type="example"><bold>EXAMPLE 3</bold> aaaaaaa</p></disp-quote>
    <p>aaaaaa</p>
    <p>aaaaaa</p>
    <disp-quote><p content-type="example"><bold>EXAMPLE</bold> aaaaaaa</p></disp-quote>
    <p>vvvkvuvhv</p>
</sec>

XSLT

    <xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    exclude-result-prefixes="xs"
    version="2.0">
    <xsl:template match="bold">
        <bold aid:cstyle="bold">
            <xsl:apply-templates />
            <xsl:if test=".='EXAMPLE' and ancestor::disp-quote[following-sibling::*[1][self::disp-quote]]">
                <xsl:for-each select="ancestor::disp-quote[following-sibling::*[1][self::disp-quote]]">
                    <xsl:value-of select="count(ancestor::disp-quote[following-sibling::*[1][self::disp-quote]])+1"/>
                </xsl:for-each>
            </xsl:if>
        </bold>
    </xsl:template>
</xsl:stylesheet>

Редактировать из комментариев :

Мой ожидаемый результат только в том случае, если он приходит с disp-quote с такими же последующими одноименными disp-quote, а затем добавляется с помощью position () Пример 1, Пример 2, Пример 3. Если он приходит в виде одинарной disp-quote, то Без изменений только Example.

Answer 1

Я думаю, что предложение Майкла использовать xsl:number - это способ, которым вы хотите использовать, если вы хотите пронумеровать все <b>EXAMPLE</b> в любом disp-quote, даже одном; если вы хотите пронумеровать их только в том случае, если в соседней группе более одного disp-quote, может помочь предложение, сделанное в комментарии:

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    exclude-result-prefixes="#all"
    version="3.0">

  <xsl:mode on-no-match="shallow-copy"/>

  <xsl:output indent="yes"/>

  <xsl:template match="sec[disp-quote]">
      <xsl:copy>
          <xsl:for-each-group select="*" group-adjacent="boolean(self::disp-quote[p/bold = 'EXAMPLE'])">
              <xsl:choose>
                  <xsl:when test="current-grouping-key() and tail(current-group())">
                      <xsl:apply-templates select="current-group()" mode="number-examples"/>
                  </xsl:when>
                  <xsl:otherwise>
                      <xsl:apply-templates select="current-group()"/>
                  </xsl:otherwise>
              </xsl:choose>
          </xsl:for-each-group>
      </xsl:copy>
  </xsl:template>

  <xsl:template match="disp-quote" mode="number-examples">
      <xsl:copy>
          <xsl:apply-templates>
              <xsl:with-param name="dq-pos" tunnel="yes" select="position()"/>
          </xsl:apply-templates>
      </xsl:copy>
  </xsl:template>

  <xsl:template match="disp-quote/p/bold[. = 'EXAMPLE']">
      <xsl:param name="dq-pos" tunnel="yes" select="()"/>
      <xsl:copy>
          <xsl:value-of select="., $dq-pos"/>
      </xsl:copy>
  </xsl:template>

</xsl:stylesheet>

https://xsltfiddle.liberty-development.net/bwe3bW/

Answer 2

Вы делаете это очень сложно (или, возможно, это действительно так?)

Я бы сделал

<xsl:template match="disp-quote//bold[.='EXAMPLE']">
  <bold aid:cstyle="bold">
    <xsl:text>EXAMPLE </xsl:text>
    <xsl:number level="any" count="bold" from="sec"/>
  </bold>
</xsl:template>