Как создать функцию: получить одно значение из файла SD-карты, используя имя файла в качестве параметра функции - PullRequest
Новая
       27

Как создать функцию: получить одно значение из файла SD-карты, используя имя файла в качестве параметра функции

0 голосов
/ 15 апреля 2020

Я ценю любое руководство или помощь, которую я могу получить в этом. Я пишу программу со значениями PID, хранящимися на SD-карте, чтобы я мог изменить их на сенсорном экране, не подключая его к своему компьютеру. Я хочу одну функцию, которую я могу вызвать с параметрами, позволяющими мне увеличивать или уменьшать число и изменять имя файла. Приведенная ниже функция - это то, что я должен изменить, увеличивается или уменьшается «pnum.txt»; однако я не могу понять, как заставить файл работать как параметр.

Я попытался сделать "" pnum.txt "" (с кавычками) в качестве символа и в виде строки, и хотя он печатается так, как должен, он не работает при вставке в функцию. Я также попытался передать все SD.open("pnum.txt", FILE_WRITE) и myFile = SD.open("pnum.txt", FILE_WRITE) как File, но это делает что-то странное - он создаст файл, когда я его открою, но не запишет в файл. Я обнаруживаю, что просто пробую одни и те же вещи снова и снова, поэтому у меня явно нет понимания, что я нигде не нахожу. Еще раз спасибо за любую помощь в этом! 

float incDecValue(float value) {

        //This is important, because the libraries are sharing pins
        pinMode(XM, OUTPUT);
        pinMode(YP, OUTPUT);

        value;
        SD.remove("pnum.txt");
        myFile = SD.open("pnum.txt", FILE_WRITE);
        myFile.print(value);
        myFile.close();
        counter = 0;
        myFile = SD.open("pnum.txt");
        if (myFile) {
          while (myFile.available()) {
            testChar[counter] = myFile.read();
            counter++;
          }
          myFile.close();
         }
         float convertedValue = atof(testChar);
         return convertedValue;
    }

И я назову это так. 

pValue = incValue(pValue+=.5);

1 Ответ

0 голосов
/ 15 апреля 2020

Поскольку я точно не знал, чего вы действительно хотите, я сделал следующие предположения:

  • Вы хотите сохранить одно значение с плавающей точкой в ​​файле с именем pnum.txt
  • Вы хотите сделать что-то с этим значением
  • Вы хотите, чтобы обработанное значение записывалось обратно в файл pnum.txt (перезаписывая содержимое)
  • Две разные функции параметризовались с fileName в качестве входных данных и значением для записи

Так что здесь полную последовательность (работает, как опубликовано), которую вы могли бы легко внедрить в свой код. Класс String не используется, и его однострочный файл предназначен только для чтения / записи: 

/* SD card pid read/write

  The circuit:
     SD card attached to SPI bus as follows:
 ** MOSI - pin 11
 ** MISO - pin 12
 ** CLK - pin 13
 ** CS - pin 4   */

#include <SPI.h>
#include <SD.h>
const uint8_t chipSelect = 4;
char dataChar[16] = {'\0'};

void setup() {
  // Open serial communications and wait for port to open:
  Serial.begin(9600);
  while (!Serial) {
    ; // wait for serial port to connect.
  }
  Serial.print("Initializing SD card...");
  // see if the card is present and can be initialized:
  if (!SD.begin(chipSelect)) {
    Serial.println("Card failed or no card present");
    return;
  }
  Serial.println("Card initialized");
}

void loop() {
  float pValue = readFileValue ("pnum.txt") + 0.5;
  writeFileValue ("pnum.txt", pValue);
}

float readFileValue (const char* fileName) {
  /* Open the file. note that only one file can be open at a time,
    so you have to close this one before opening another.*/
  File dataFile = SD.open(fileName, FILE_READ);
  // if the file is available, write to it:
  if (dataFile) {
    char c;
    uint8_t i = 0;
    while (dataFile.available()) {
      c = dataFile.read();   // Read char by char
      if (c != '\n') {      // As long no line terminator
        dataChar[i] = c;
        i++;
      }
      else {
        dataChar[i] = '\0';  // Terminate char array properly
        dataFile.close();
        break;
      }
    }
    Serial.print("Success writing content: ");
    Serial.println(dataChar);
  }
  else {   // If the file isn't open, pop up an error:
    Serial.print("Error opening requested file: ");
    Serial.println(fileName);
  }
  float fileVal = atof(dataChar);;
  return fileVal;
}

bool writeFileValue (const char* fileName, float fileVal) {
  SD.remove(fileName); // Delete the existing file if existing 
  File dataFile = SD.open(fileName, FILE_WRITE);
  // If the file opened okay, write to it
  if (dataFile) {
    // dtostrf(floatvar, StringLengthIncDecimalPoint, numVarsAfterDecimal, charbuf);
    dtostrf(fileVal, 5, 2, dataChar);  // Not really needed for this simple issue, but ..
    Serial.print("Writing to file: ");
    Serial.println(fileName);
    dataFile.println(dataChar);
    // Close the file
    dataFile.close();
    Serial.println("Success saving done");
    return true;
  } else {
    // if the file didn't open, print an error:
    Serial.println("Error opening file: ");
    Serial.println(fileName);
    return false;
  }
}
...