Условное форматирование с именованными диапазонами

Question

Я пытаюсь отформатировать ячейки таблицы, когда первое значение строки и столбца заголовка соответствуют значениям из именованного диапазона в Google Sheets. Я решил ее как формулу с TRUE и FALSE, но я не могу принять ее для условного форматирования.

Пример листа: https://docs.google.com/spreadsheets/d/1MpViBGIOYoeMpB2zpb81hwlNOJcShP86OHYlI92mKGA/edit?usp=sharing

Мой источник таблица: -> именованные диапазоны "mapping_name" и "mapping"

+-------+--------+---------+-----------+
|       |        |         |           |
+-------+--------+---------+-----------+
| name1 | Monday | Tuesday |           |
| name2 | Monday |         | Wednesday |
| name3 |        |         |           |
+-------+--------+---------+-----------+

Моя таблица для форматирования:

+-------+--------+---------+-----------+--+--+
|       | Monday | Tuesday | Wednesday |  |  |
+-------+--------+---------+-----------+--+--+
| name1 | True   | True    | True      |  |  |
| name2 | True   | True    | False     |  |  |
| name3 | False  | False   | False     |  |  |
+-------+--------+---------+-----------+--+--+

Моя формула выглядит так

=OR(ARRAYFORMULA((B$34 = index(mapping;match($A35;mapping_name;0))) * ($A35 = index(mapping_name;match($A35;mapping_name;0)))))

B34 - заголовок с рабочими днями A35 - имя столбца

Формула работает, но я не могу перевести ее в формат, который работает для условного форматирования. Любая помощь будет оценена!

Answer 1

В вашей таблице «ожидаемых результатов» я использовал эту формулу для условного форматирования

=ISNUMBER(MATCH($A18&"_"&B$17, ArrayFormula(TRANSPOSE(SPLIT(TEXTJOIN("@", 1, $A$4:$A$6&"_"&$B$4:$D$6), "@"))), 0))

Или, если вы хотите использовать именованные диапазоны, попробуйте

=ISNUMBER(MATCH($A18&"_"&B$17, ArrayFormula(TRANSPOSE(SPLIT(TEXTJOIN("@", 1, INDIRECT("mapping_name")&"_"&INDIRECT("mapping")), "@"))), 0))

(Примечание использование кавычек вокруг именованных диапазонов.)

Посмотрите, подходит ли вам это?

Answer 2

попробовать:

=MATCH(B4, $B$17:$D$17, 0)=COLUMN(A1)