Реализация AT-POS для возврата объекта вместо списка вещей - PullRequest
Новая
       7

Реализация AT-POS для возврата объекта вместо списка вещей

6 голосов
/ 03 февраля 2020

У меня есть следующий класс: 

class Names {
    has @!names;

    method add-name( $name ) { @!names.push($name) }

    multi method AT-POS( ::?CLASS:D: $index ) {
        my $new-names-obj = Names.new;

        for @!names[$index] -> $name {
            $new-names-obj.add-name($name);
        }

        return $new-names-obj;
    }

    method gist {
        @!names.join("\n")
    }
}

Я хотел бы иметь возможность нарезать объект Names, а возвращаемое значение должно быть другим объектом Names, элементы которого вырезаны из оригинальный Names объект. Например: 

my $original = Names.new;
$original.add-name($_) for <jonathan joseph jotaro josuke giorno>;
my $sliced-off = $original[0..2];

say $original.^name;   #=> Names
say $original;         #=> jonathan, joseph, jotaro, josuke, giorno
say $sliced-off.^name; #=> List
say $sliced-off;       #=> (jonathan joseph jotaro)

Когда передается один аргумент, он работает как ожидалось и как описано в этом ответе , но это не относится к диапазону, поскольку AT-POS в конечном итоге вызывается несколько раз и собирая результаты в списке. Поэтому мне интересно, можно ли при использовании диапазона вернуть один объект $sliced-off, а не список результатов.

Ответы [ 2 ]

8 голосов
/ 03 февраля 2020

Метод AT-POS предназначен для того, чтобы объект мог действовать как объект Positional. Это не , что вы хотите. Вы хотите object[slice] DWIM.

Лучший способ добиться этого - создать postcircumfic:<[ ]> (мульти) кандидата для вашего объекта: 

class A {
    method slice(@_) {
        say @_;  # just to show the principle
    }
}
sub postcircumfix:<[ ]>($object, *@indices) {
   constant &slicer = &postcircumfix:<[ ]>;
   $object ~~ A
     ?? $object.slice(@indices)
     !! slicer($object, @indices)
}

A.new[1,2,4,5];  # [1 2 4 5]

my @a = ^10;     # check if foo[] still works
say @a[1,2,4,5]; # (1 2 4 5)

Чтобы убедиться, что общий поведение @a[] сохраняется, мы сохраняем значение postcircumfix:[ ]> системы во время компиляции (с constant). Затем во время выполнения, когда объект является , а не нужного класса, вызвать исходную версию postcircumfix:<[ ]> с заданными параметрами.

4 голосов
/ 04 февраля 2020

Опираясь на рекомендации Лиз: 

class Names {
    has @.names;                                      # Make public so [] can access.
    method new (*@names) { nextwith :@names }         # Positional .new constructor.
    submethod BUILD (:@!names) {}                     # Called by nextwith'd Mu new.
    multi sub postcircumfix:<[ ]>                     # Overload [] subscript.
      ( Names $n, $index, *@indices )                 # Why `$index, *@indices`?
      is default is export                            # And why `is default`?
      { Names.new: |$n.names[ |$index, |@indices ] }  # Why? See my comment 
    method gist { @!names.join(', ') }                # below Liz's answer.
}
import Names;

my $original = Names.new: <jonathan joseph jotaro josuke giorno>;
my $sliced-off = $original[0..2];

say $original.^name;   #=> Names
say $original;         #=> jonathan, joseph, jotaro, josuke, giorno
say $sliced-off.^name; #=> Names
say $sliced-off;       #=> jonathan, joseph, jotaro

PLMK, если код или объяснение неадекватны.

...