ESP8266 падает после простого http-запроса - PullRequest
Новая
       42

ESP8266 падает после простого http-запроса

0 голосов
/ 11 января 2020

Я работаю с модулем NodeMCU V3. Всякий раз, когда я пытаюсь сделать http-запрос к моему серверу, модуль вылетает.

Вот код: 

void setup() {
    WiFi.begin("wifi-name", "wifi-password");  

    while (WiFi.status() != WL_CONNECTED) {  //Wait for the WiFI to connect }
}

void loop() {
   HTTPClient http; 
   WiFiClient client;

   http.begin( client, "server-address" );  

   int httpCode = http.GET();  
   String payload = http.getString();  //Get the response payload

   Serial.println(httpCode);   //Print HTTP return code
   Serial.println(payload);    //Print request response payload

   http.end();  //Close connection

   delay( 1000 );
}

Вот результат, как видно на мониторе последовательного порта: 

200
["JSON response from the server"]

Exception (28):
epc1=0x40212e82 epc2=0x00000000 epc3=0x00000000 excvaddr=0x000001b6 depc=0x00000000

>>>stack>>>

ctx: cont
sp: 3ffffc90 end: 3fffffc0 offset: 01a0
3ffffe30:  00000000 4bc6a7f0 0000333f 3ffee5f8  
3ffffe40:  00000000 00000000 4bc6a7f0 00000000  
[...] 
3fffffb0:  feefeffe feefeffe 3ffe84e8 40100c41  
<<<stack<<<

Странно то, что он правильно получает ответ от сервера, но затем, примерно через секунду, выплевывает исключение на последовательный монитор и сбрасывает его. Сначала я подумал, что это может быть из-за того, что я одновременно запускаю ESP8266WebServer, но все равно происходит сбой, даже когда я запускаю самый простой пример c, который я мог найти в inte rnet. Я попытался скомпилировать тот же код в Arduino IDE вместо PlatformIO или даже с использованием другого NodeMCU, но безрезультатно.

РЕДАКТИРОВАТЬ: после того, как вы поиграете немного больше, кажется, что установка задержки по крайней мере 10 секунд делает NodeMCU cra sh после 3 запросов, а не после первого. Может быть, переполнение памяти после нескольких запросов? Я пропустил важную часть, которая должна подготовить ESP8266 к новому запросу?

1 Ответ

3 голосов
/ 12 января 2020

Нет необходимости заново создавать WiFi и HTTP-клиенты в loop() снова и снова. Вы можете объявить их один раз во всем мире. Вот стабильная версия этого простого эскиза: 

#include <Arduino.h>

#include <ESP8266WiFi.h>
#include <ESPHTTPClient.h>

HTTPClient http; 
WiFiClient client;

void setup() {
  Serial.begin(115200);
  Serial.println();
  WiFi.begin("****", "****");  

  Serial.print("Connecting to WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("done.");
}

void loop() {
  http.begin(client, "http://httpbin.org/get"); // <1KB payload
//  http.begin(client, "http://www.geekstips.com/esp8266-arduino-tutorial-iot-code-example/"); // 30KB payload

  int httpCode = http.GET();  
  String payload = http.getString();  //Get the response payload

  Serial.println(httpCode);   //Print HTTP return code
  Serial.println(payload);    //Print request response payload

  http.end();  //Close connection

  Serial.printf("Free heap: %d\n", ESP.getFreeHeap());
  delay(1000);
}

Сообщаемая свободная куча очень стабильна во времени. Обратите внимание на второй URL-адрес, который я добавил для проверки в строке комментариев. Это http.getString() удобно и хорошо работает для небольших ресурсов, но дает неожиданные, то есть неправильные результаты для больших ресурсов - вы видите только небольшую часть тела, напечатанного на консоль.

Для больших полезных нагрузок вы должны использовать низкий -Уровень WiFiClient напрямую и читать / анализировать построчно или посимвольно. См. Документацию в https://arduino-esp8266.readthedocs.io/en/latest/esp8266wifi/client-examples.html для шаблона. 

void loop()
{
  WiFiClient client;

  Serial.printf("\n[Connecting to %s ... ", host);
  if (client.connect(host, 80))
  {
    Serial.println("connected]");

    Serial.println("[Sending a request]");
    client.print(String("GET /") + " HTTP/1.1\r\n" +
                 "Host: " + host + "\r\n" +
                 "Connection: close\r\n" +
                 "\r\n"
                );

    Serial.println("[Response:]");
    while (client.connected() || client.available())
    {
      if (client.available())
      {
        String line = client.readStringUntil('\n');
        Serial.println(line);
      }
    }
    client.stop();
    Serial.println("\n[Disconnected]");
  }
  else
  {
    Serial.println("connection failed!]");
    client.stop();
  }
  delay(5000);
}
...