Как восстановить Outlook письма для удаленной учетной записи электронной почты - PullRequest
Новая
       17

Как восстановить Outlook письма для удаленной учетной записи электронной почты

0 голосов
/ 26 марта 2020

Я случайно удалил свою учетную запись электронной почты и все электронные письма в этой учетной записи. Есть ли шанс восстановить письма? Как я могу восстановить это? Спасибо.

1 Ответ

0 голосов
/ 04 апреля 2020

Четыре месяца go Я бы согласился с комментарием Om3r, в котором указано расположение магазинов Outlook. Но я купил новый ноутбук в декабре, и теперь файлы Outlook находятся не там, где в документации указано, что они должны быть. Хуже того, я не могу получить доступ к папкам, содержащим файлы Outlook, с помощью проводника, хотя могу найти их с помощью VBA.

В приведенном ниже макросе выполняется поиск на диске C файлов с расширением OST или PST. Я не могу обещать, что этот макрос найдет ваш потерянный магазин, но, если он все еще находится на вашем диске c, он найдет его. Если вы найдете недостающее хранилище, вам, вероятно, придется использовать VBA, чтобы переместить его в какое-то доступное место.

Скопируйте приведенный ниже макрос в книгу с поддержкой макросов и запустите его. Во время работы активная рабочая таблица будет выглядеть следующим образом: 

1923 Folders to search
 327 Folders searched           

     Store       Size      Date Folder
     $ILJARJ0.pst   212   28Mar20 C:\$Recycle.Bin\S-1-5-21-3957073674-21115239-22921093-1001
     $IMS96DJ.pst   212   28Mar20 C:\$Recycle.Bin\S-1-5-21-3957073674-21115239-22921093-1001

В двух верхних строках отображается грубый индикатор прогресса. На моем ноутбуке процедура завершается поиском 69190 папок. Я не знаю, почему в моей корзине есть файлы PST. Я ничего не сделал 28 марта. Когда процедура завершится, будет автоматически установлен список всех найденных макросов. На моем ноутбуке нет места, где я ожидал, а некоторые - дубликаты. Я надеюсь, что вы найдете свой магазин. 

Option Explicit
Sub SearchForStoresOnC()

  ' Searches drive C for files with an extension of PST or OST
  ' Warning: overwrites the active workbook

  Dim ErrNum As Long
  Dim FileAttr As Long
  Dim FileName As String
  Dim FldrName As String
  Dim RowCrnt As Long
  Dim ToSearch As Collection

  Cells.EntireRow.Delete
  Range("A1").Value = 0
  Range("A2").Value = 0
  Range("B1").Value = "Folders to search"
  Range("B2").Value = "Folders searched"
  Range("B4").Value = "Store"
  With Range("C4")
    .Value = "Size"
    .HorizontalAlignment = xlRight
  End With
  With Range("D4")
    .Value = "Date"
    .HorizontalAlignment = xlRight
  End With
  Range("E4") = "Folder"
  RowCrnt = 5

  Set ToSearch = New Collection
  ' Load ToSearch with drive to search.
  ToSearch.Add "C:"

  Do While ToSearch.Count > 0

    FldrName = ToSearch(1)
    ToSearch.Remove 1

    Err.Clear
    ErrNum = 0
    On Error Resume Next
    ' Stores are unlikely to be hidden but can be in folders that are hidden
    FileName = Dir$(FldrName & "\*.*", vbDirectory + vbHidden + vbSystem)
    ErrNum = Err.Number
    On Error GoTo 0
    If ErrNum <> 0 Then
      'Debug.Print "Dir error: " & FldrName
    Else
      Do While FileName <> ""
        If FileName = "." Or FileName = ".." Then
          ' Ignore pointers
        Else
          Err.Clear
          On Error Resume Next
          FileAttr = GetAttr(FldrName & "\" & FileName)
          ErrNum = Err.Number
          On Error GoTo 0
          If ErrNum = 0 Then
            ' Ignore file and folders which give errors
            If (FileAttr And vbDirectory) = 0 Then
              ' File
              'Debug.Assert False
               Select Case Right$(FileName, 4)
                 Case ".pst", ".ost"
                 Cells(RowCrnt, "B").Value = FileName
                 With Cells(RowCrnt, "C")
                   .Value = FileLen(FldrName & "\" & FileName)
                   .NumberFormat = "#,##0"
                 End With
                 With Cells(RowCrnt, "D")
                   .Value = FileDateTime(FldrName & "\" & FileName)
                   .NumberFormat = "dmmmyy"
                 End With
                 Cells(RowCrnt, "E").Value = FldrName
                 RowCrnt = RowCrnt + 1
               End Select
            Else
              ' Directory
              ToSearch.Add FldrName & "\" & FileName
            End If  ' File or Directory
          Else
            'Debug.Print "FileAttr error: " & FldrName & "\" & FileName
          End If  ' FileAttr does not give an error
        End If ' Pointer or (File or Directory)
        FileName = Dir$
      Loop  ' For each pointer, file and sub-directory in folder
    End If  ' Dir$ gives error

    Range("A1") = ToSearch.Count
    Range("A2") = Range("A2") + 1
    DoEvents

  Loop  'until ToSearch empty

  Columns.AutoFit

End Sub
...