Сохраняйте Excel mailmerge в PDF только в последней строке с данными - PullRequest
Новая
       113

Сохраняйте Excel mailmerge в PDF только в последней строке с данными

0 голосов
/ 01 марта 2020

Я использую код, который использует mailmerge из листа Excel в мой шаблон слова, а затем переходит к сохранению всех строк моего листа Excel в PDF (конечно же, в шаблоне слова). - Код работает отлично.

Код был взят с этого форума:

https://www.msofficeforums.com/mail-merge/21803-mailmerge-tips-tricks.html

Как выглядит мой лист Excel:

A1-E1 = Заголовки
A2-E2 = данные
A3-E3 = данные
A4-E4 = данные
и т. Д. ...

Как в настоящее время работает код:
Код сохраняет все строки данных из таблицы Excel в мой шаблон слов (с mailmerge), а затем в PDF.

Моя цель:
Я хочу изменить код, чтобы он сохранял только последнюю строку данных в листе Excel в мой шаблон слов (с mailmerge), а затем в PDF. 

Sub RunMerge()
' Sourced from: https://www.msofficeforums.com/mail-merge/21803-mailmerge-tips-tricks.html
' Note: this code requires a reference to the Word object model to be set, via Tools|References in the VBE.
Application.ScreenUpdating = False
Dim StrMMSrc As String, StrMMDoc As String, StrMMPath As String, StrName As String
Dim i As Long, j As Long
Const StrNoChr As String = """*./\:?|"
Dim wdApp As New Word.Application, wdDoc As Word.Document
wdApp.Visible = False
wdApp.DisplayAlerts = wdAlertsNone
StrMMSrc = ThisWorkbook.FullName
StrMMPath = ThisWorkbook.Path & "\"
StrMMDoc = StrMMPath & "MailMergeDocument.doc"
Set wdDoc = wdApp.Documents.Open(Filename:=StrMMDoc, AddToRecentFiles:=False, ReadOnly:=True, Visible:=False)
With wdDoc
  With .MailMerge
    .MainDocumentType = wdFormLetters
    .OpenDataSource Name:=StrMMSrc, ReadOnly:=True, AddToRecentFiles:=False, _
      LinkToSource:=False, Connection:="Provider=Microsoft.ACE.OLEDB.12.0;User ID=Admin;" & _
      "Data Source=StrMMSrc;Mode=Read;Extended Properties=""HDR=YES;IMEX=1"";", _
      SQLStatement:="SELECT * FROM `Sheet1$`"
    For i = 1 To .DataSource.RecordCount
      .Destination = wdSendToNewDocument
      .SuppressBlankLines = True
      With .DataSource
        .FirstRecord = i
        .LastRecord = i
        .ActiveRecord = i
        If Trim(.DataFields("Name")) = "" Then Exit For
        StrName = .DataFields("Name")
      End With
      .Execute Pause:=False
      For j = 1 To Len(StrNoChr)
        StrName = Replace(StrName, Mid(StrNoChr, j, 1), "_")
      Next
      StrName = Trim(StrName)
      With wdApp.ActiveDocument
        'Add the name to the footer
        '.Sections(1).Footers(wdHeaderFooterPrimary).Range.InsertBefore StrName
        '.SaveAs Filename:=StrMMPath & StrName & ".docx", FileFormat:=wdFormatXMLDocument, AddToRecentFiles:=False
        ' and/or:
        .SaveAs Filename:=StrMMPath & StrName & ".pdf", FileFormat:=wdFormatPDF, AddToRecentFiles:=False
        .Close SaveChanges:=False
      End With
    Next i
    .MainDocumentType = wdNotAMergeDocument
  End With
  .Close SaveChanges:=False
End With
wdApp.DisplayAlerts = wdAlertsAll
wdApp.Quit
Set wdDoc = Nothing: Set wdApp = Nothing
Application.ScreenUpdating = False
End Sub

Заранее спасибо.

1 Ответ

0 голосов
/ 01 марта 2020

Заменить: 

For i = 1 To .DataSource.RecordCount

на: 

i = .DataSource.RecordCount

или, если используются строки ниже, чем в других столбцах: 

i = ActiveSheet.Range("A" & ActiveSheet.Rows.Count).End(xlUp).Row - 1

где ' A '- это любой столбец, не содержащий данных ниже последней записи и удаляющий оба: 

If Trim(.DataFields("Name")) = "" Then Exit For

и: 

Next i
...