Точечный свет двигаться с камерой - PullRequest
Новая
       81

Точечный свет двигаться с камерой

1 голос
/ 26 марта 2020

В настоящее время я работаю над OpenGL, чтобы добавить несколько источников света в мою сцену (направленный источник света, точечный источник света и точечный источник света). Кажется, мой направленный свет и точечный свет работают, но мой точечный свет все еще следует за камерой. Я хочу установить положение этого точечного источника света в произвольном месте, например (10, 5, 2). Итак, я создал фрагментный шейдер для управления несколькими источниками света с этой структурой для точечного источника света: 

struct PointLight {    
   vec3 position;
   vec3  color;

   float constant;
   float linear;
   float quadratic;  };

А вот код, куда я отправляю данные фрагментному шейдеру: 

glm::vec3 pos(-10.f, 5.f, 0.f);
pos = glm::normalize(glm::vec3(viewMatrix * glm::vec4(pos, 1.)));
glUniform3f(pointLightPositionLocation, pos.x, pos.y, pos.z);
glUniform3f(pointLightColorLocation, 0.0f, 1.0f, 0.0f);
glUniform1f(pointLightConstantLocation, 1.0f);
glUniform1f(pointLightLinearLocation, 0.09f);
glUniform1f(pointLightQuadraticLocation, 0.032f);

Положение света точки выражается в пространстве вида.

Вершинный шейдер: 

#version 330

layout(location = 0) in vec3 aPosition;
layout(location = 1) in vec3 aNormal;
layout(location = 2) in vec2 aTexCoords;

out vec3 vViewSpacePosition;
out vec3 vViewSpaceNormal;
out vec2 vTexCoords;
out vec3 vFragPos; 

uniform mat4 uModelViewProjMatrix;
uniform mat4 uModelViewMatrix;
uniform mat4 uNormalMatrix;

void main()
{
    vViewSpacePosition = vec3(uModelViewMatrix * vec4(aPosition, 1));
    vViewSpaceNormal = normalize(vec3(uNormalMatrix * vec4(aNormal, 0)));
    vTexCoords = aTexCoords;
    gl_Position =  uModelViewProjMatrix * vec4(aPosition, 1);
}

И, наконец, функция, в которой я вычисляю цвет фрагмента из света точки: 

vec3 calculatePointLight(PointLight light) {
    vec3 N = normalize(vViewSpaceNormal);
    vec3 L = normalize(light.position - vViewSpacePosition);
    vec3 V = normalize(-vViewSpacePosition);
    vec3 H = normalize(L + V);

    vec4 baseColorFromTexture = SRGBtoLINEAR(texture(uBaseColorTexture, vTexCoords));
    vec4 baseColor = baseColorFromTexture * uBaseColorFactor;
    float NdotL = clamp(dot(N, L), 0, 1);
    float NdotV = clamp(dot(N, V), 0, 1);
    float NdotH = clamp(dot(N, H), 0, 1);
    float VdotH = clamp(dot(V, H), 0, 1);

    float metallic = texture(uMetallicRoughnessTexture, vTexCoords).z * uMetallicFactor;
    float roughness = texture(uMetallicRoughnessTexture, vTexCoords).y * uRoughnessFactor;

    vec3 cDiff = mix(baseColor.rgb * (1 - dielectricSpecular.r), black, metallic);
    vec3 f0 = mix(dielectricSpecular, baseColor.rgb, metallic);
    float a = uRoughnessFactor * roughness;
    float a2 = a * a;

    // You need to compute baseShlickFactor first
    float baseShlickFactor = (1 - VdotH);
    float shlickFactor = baseShlickFactor * baseShlickFactor; // power 2
    shlickFactor *= shlickFactor; // power 4
    shlickFactor *= baseShlickFactor; // power 5
    vec3 F = f0 + (1 - f0) * shlickFactor;

    float deno = NdotL * sqrt(NdotV * NdotV * (1 - a2) + a2) + NdotV * sqrt(NdotL* NdotL * (1 - a2) + a2);
    float Vis;
    if (deno == 0.) {
        Vis = 0;
    }
    else {
        Vis = 0.5 / deno;
    }

    deno = M_PI * (NdotH * NdotH * (a2 - 1) + 1) * (NdotH * NdotH * (a2 - 1) + 1);
    float D;
    if (deno == 0.) {
        D = 0;
    }
    else {
        D = a2 / deno;
    }

    vec3 diffuse = cDiff * M_1_PI;
    vec3 f_diffuse = (1 - F) * diffuse;
    vec3 f_specular = F * Vis * D;

    vec4 emissive = texture(uEmissiveTexture, vTexCoords) * vec4(uEmissiveFactor, 1);

    vec4 occlusion = texture(uOcclusionTexture, vTexCoords);

    // attenuation
    float distance    = length(light.position - vViewSpacePosition);
    float attenuation = 1.0 / (light.constant + light.linear * distance + 
                 light.quadratic * (distance * distance));

    f_diffuse *= attenuation;
    f_specular *= attenuation;

    vec3 color = (f_diffuse + f_specular) * light.color * NdotL + emissive.xyz;
    color = mix(color, color * occlusion.x, uOcclusionStrength);
    color = LINEARtoSRGB(color);
    return color;
}

Эта функция довольно сложна из-за шероховатости металла c, и множество линий не связано с проблемой. Подводя итог, эта функция очень похожа на calcDirectionalLight (который работает), но различия заключаются в том, что я добавил ослабление, и L - это light.position - FragPos вместо light.direction. Я не понимаю, в чем проблема, похоже, что данные не указаны в правильном месте или я что-то забыл.

1 Ответ

0 голосов
/ 27 марта 2020

Я нашел решение, и оно очень простое. Я скопировал эту строку: pos = glm::normalize(glm::vec3(viewMatrix * glm::vec4(pos, 1.))); из направленного источника света (я заменил 0 на 1 и dirLight положением) К сожалению, я забыл удалить нормализацию, поэтому точечный источник света близок к (0, 0, 0): положению камеры. Этот результат убедил меня, что данные были указаны не в том месте, но это не так.

...